TARGET = stem_QtGui
VPATH = /sf/mw/qt/src/gui
MMP_RULES += NOEXPORTLIBRARY
defBlock = "deffile /sf/mw/qt/src/s60installs/~/QtGui.def"
MMP_RULES += defBlock
QPRO_PWD = $$PWD
QT = core
DEFINES += QT_BUILD_GUI_LIB QT_NO_USING_NAMESPACE
win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x65000000
!win32:!embedded:!mac:!symbian:CONFIG += x11
unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
include(/sf/mw/qt/src/qbase.pri)
contains(QT_CONFIG, x11sm):CONFIG += x11sm
#platforms
x11:include(kernel/x11.pri)
mac:include(kernel/mac.pri)
win32:include(kernel/win.pri)
embedded:include(embedded/embedded.pri)
symbian {
include(/sf/mw/qt/src/gui/kernel/symbian.pri)
# include(/sf/mw/qt/src/gui/s60framework/s60framework.pri)
}
#modules
include(/sf/mw/qt/src/gui/animation/animation.pri)
include(kernel/kernel.pri)
include(/sf/mw/qt/src/gui/image/image.pri)
include(/sf/mw/qt/src/gui/painting/painting.pri)
include(/sf/mw/qt/src/gui/text/text.pri)
include(/sf/mw/qt/src/gui/styles/styles.pri)
include(/sf/mw/qt/src/gui/widgets/widgets.pri)
include(/sf/mw/qt/src/gui/dialogs/dialogs.pri)
include(/sf/mw/qt/src/gui/accessible/accessible.pri)
include(/sf/mw/qt/src/gui/itemviews/itemviews.pri)
include(/sf/mw/qt/src/gui/inputmethod/inputmethod.pri)
include(/sf/mw/qt/src/gui/graphicsview/graphicsview.pri)
include(/sf/mw/qt/src/gui/util/util.pri)
include(/sf/mw/qt/src/gui/statemachine/statemachine.pri)
include(/sf/mw/qt/src/gui/math3d/math3d.pri)
include(/sf/mw/qt/src/gui/effects/effects.pri)
contains(QT_CONFIG, egl): include(/sf/mw/qt/src/gui/egl/egl.pri)
embedded: QT += network
QMAKE_LIBS += $$QMAKE_LIBS_GUI
contains(DEFINES,QT_EVAL):include($$QT_SOURCE_TREE/src/corelib/eval.pri)
QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtGui.dynlist
DEFINES += Q_INTERNAL_QAPP_SRC
symbian: {
TARGET.UID3=0x2001B2DD
# ro-section in gui can exceed default allocated space, so move rw-section a little further
QMAKE_LFLAGS.ARMCC += --rw-base 0x800000
QMAKE_LFLAGS.GCCE += -Tdata 0xC00000
# Partial upgrade SIS file
vendorinfo = \
"; Localised Vendor name" \
"%{\"Nokia, Qt\"}" \
" " \
"; Unique Vendor name" \
":\"Nokia, Qt\"" \
" "
pu_header = "; Partial upgrade package for testing QtGui changes without reinstalling everything" \
"$${LITERAL_HASH}{\"Qt gui\"}, (0x2001E61C), $${QT_MAJOR_VERSION},$${QT_MINOR_VERSION},$${QT_PATCH_VERSION}, TYPE=PU"
partial_upgrade.pkg_prerules = pu_header vendorinfo
partial_upgrade.sources = qtgui.dll
partial_upgrade.path = c:/sys/bin
DEPLOYMENT = partial_upgrade $$DEPLOYMENT
}