mkspecs/docml2bin.prf
author Dremov Kirill (Nokia-D-MSW/Tampere) <kirill.dremov@nokia.com>
Wed, 18 Aug 2010 10:05:37 +0300
changeset 21 4633027730f5
parent 7 923ff622b8b9
child 23 e6ad4ef83b23
permissions -rw-r--r--
Revision: 201031 Kit: 201033

exists(hb_install.prf):include(hb_install.prf)
else:include($${HB_BUILD_DIR}/hb_install.prf)
include(hb_functions.prf)

QMAKE_DOCML2BIN = $$hbToolCommand(docml2bin) 
 
docml2bin.input = DOCML
docml2bin.output = ${QMAKE_FILE_IN}.bin
docml2bin.commands = "$$QMAKE_DOCML2BIN" -s "${QMAKE_FILE_IN}" -t "${QMAKE_FILE_OUT}"
docml2bin.name = DOCML2BIN ${QMAKE_FILE_IN}
docml2bin.CONFIG = no_link

for(DOCMLFILE, $$list($$unique(DOCML))) {
    DOCMLFILE_PWD = $${_PRO_FILE_PWD_}/$${DOCMLFILE}
    rcc.depends += $${DOCMLFILE_PWD}.bin

    BLD_INF_RULES.prj_extensions += "START EXTENSION qt/qmake_extra_pre_targetdep.export" \
        "OPTION PREDEP_TARGET $${DOCMLFILE_PWD}.bin" \
        "OPTION DEPS $${DOCMLFILE_PWD}" \
        "OPTION COMMAND $${QMAKE_DOCML2BIN} -s $${DOCMLFILE_PWD} -t $${DOCMLFILE_PWD}.bin" \
        "END"    
}

QMAKE_EXTRA_COMPILERS += docml2bin