1 isEmpty(TEMPLATE):TEMPLATE=app

     2 CONFIG += qt warn_on console depend_includepath

     3 

     4 qtAddLibrary(QtTest)

     5 

     6 symbian:{

     7     TARGET.EPOCHEAPSIZE = 0x100000 0x2000000

     8 #    DEFINES += QTEST_NO_SPECIALIZATIONS

     9     TARGET.CAPABILITY="ALL -TCB"

    10     RSS_RULES ="group_name=\"QtTests\";" 

    11 }

    12 

    13 # prefix test binary with tst_

    14 !contains(TARGET, ^tst_.*):TARGET = $$join(TARGET,,"tst_")

    15 

    16 ########################################################################

    17 # Use install rule to run test application.

    18 # This lets you do 'make install' on a test to both build and run it,

    19 # and lets you easily build and run all tests from the parent directory.

    20 # ----------------------------------------------------------------------

    21 

    22 runme.files                =

    23 runme.path                 = .

    24 !isEmpty(DESTDIR): runme.commands = cd ./$(DESTDIR) &&

    25 macx:      runme.commands += ./$(QMAKE_TARGET).app/Contents/MacOS/$(QMAKE_TARGET)

    26 else:unix: runme.commands += ./$(QMAKE_TARGET)

    27 else:win32: {

    28     CONFIG(debug, debug|release):runme.commands += debug\\$(QMAKE_TARGET)

    29     else:runme.commands += release\\$(QMAKE_TARGET)

    30 }

    31 embedded:  runme.commands += -qws

    32 INSTALLS += runme

    33 

    34 

    35 ########################################################################