|
1 build_pass:console: { |
|
2 warning("QAxServer applications cannot be console applications.") |
|
3 warning("Remove 'console' from your CONFIG.") |
|
4 } |
|
5 |
|
6 ACTIVEQT_VERSION = $$VERSION |
|
7 isEmpty(ACTIVEQT_VERSION):ACTIVEQT_VERSION = 1.0 |
|
8 |
|
9 DEFINES += QAXSERVER |
|
10 |
|
11 ACTIVEQT_IDE = makefile |
|
12 equals(TEMPLATE_PREFIX, "vc"):ACTIVEQT_IDE = VisualStudio |
|
13 equals(TEMPLATE, "vcapp"):ACTIVEQT_IDE = VisualStudio |
|
14 equals(TEMPLATE, "vclib"):ACTIVEQT_IDE = VisualStudio |
|
15 |
|
16 equals(ACTIVEQT_IDE, "VisualStudio") { |
|
17 ACTIVEQT_IDC = $${QMAKE_IDC} |
|
18 ACTIVEQT_IDL = $${QMAKE_IDL} |
|
19 ACTIVEQT_TARGET = "$(TargetPath)" |
|
20 win32-msvc { |
|
21 ACTIVEQT_NEWLINE = $$escape_expand(\t) |
|
22 ACTIVEQT_OUTPUT = $(IntDir)/$${TARGET} |
|
23 } else { |
|
24 ACTIVEQT_NEWLINE = $$escape_expand(\n\t) |
|
25 ACTIVEQT_OUTPUT = $(IntDir)$${TARGET} |
|
26 } |
|
27 ACTIVEQT_TLBOUT = "$(TargetDir)/$${TARGET}.tlb" |
|
28 GENERATED += $${OBJECTS_DIR}/$${TARGET}.idl $${ACTIVEQT_TLBOUT} |
|
29 } |
|
30 equals(ACTIVEQT_IDE, "makefile") { |
|
31 ACTIVEQT_IDC = -$(IDC) |
|
32 ACTIVEQT_IDL = -$(IDL) |
|
33 ACTIVEQT_NEWLINE = $$escape_expand(\n\t) |
|
34 ACTIVEQT_TARGET = $(DESTDIR_TARGET) |
|
35 ACTIVEQT_OUTPUT = $(OBJECTS_DIR)/$${TARGET} |
|
36 isEmpty(DESTDIR) { |
|
37 ACTIVEQT_TLBOUT = $${TARGET}.tlb |
|
38 } else { |
|
39 ACTIVEQT_TLBOUT = $${DESTDIR}/$${TARGET}.tlb |
|
40 } |
|
41 } |
|
42 |
|
43 !qaxserver_no_postlink { |
|
44 !isEmpty(QMAKE_POST_LINK):QMAKE_POST_LINK += $$quote($$ACTIVEQT_NEWLINE) |
|
45 QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /idl $${ACTIVEQT_OUTPUT}.idl -version $${ACTIVEQT_VERSION}$${ACTIVEQT_NEWLINE}) |
|
46 !isEmpty(RC_FILE) { |
|
47 QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_OUTPUT}.tlb"$$ACTIVEQT_NEWLINE) |
|
48 QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /tlb $${ACTIVEQT_OUTPUT}.tlb$$ACTIVEQT_NEWLINE) |
|
49 } else { |
|
50 QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDL "$${ACTIVEQT_OUTPUT}.idl" /nologo /tlb "$${ACTIVEQT_TLBOUT}"$$ACTIVEQT_NEWLINE) |
|
51 message("No rc-file linked into project; type library will be a separate file.") |
|
52 } |
|
53 QMAKE_POST_LINK += $$quote($$ACTIVEQT_IDC $${ACTIVEQT_TARGET} /regserver) |
|
54 QMAKE_CLEAN += $${ACTIVEQT_OUTPUT}.idl $${ACTIVEQT_OUTPUT}.tlb |
|
55 } |
|
56 |
|
57 qt:!target_qt { |
|
58 CONFIG(debug, debug|release) { |
|
59 QMAKE_LIBS_QT_ENTRY = -lQAxServerd |
|
60 } else { |
|
61 QMAKE_LIBS_QT_ENTRY = -lQAxServer |
|
62 } |
|
63 dll:QMAKE_LIBS += $$QMAKE_LIBS_QT_ENTRY |
|
64 } |