1 # MMF Phonon backend

     2 

     3 QT += phonon

     4 TARGET = phonon_mmf

     5 PHONON_MMF_DIR = $$QT_SOURCE_TREE/src/3rdparty/phonon/mmf

     6 

     7 # Uncomment the following line in order to use the CDrmPlayerUtility client

     8 # API for audio playback, rather than CMdaAudioPlayerUtility.

     9 #CONFIG += phonon_mmf_audio_drm

    10 

    11 phonon_mmf_audio_drm {

    12     LIBS += -lDrmAudioPlayUtility

    13     DEFINES += QT_PHONON_MMF_AUDIO_DRM

    14 } else {

    15     LIBS += -lmediaclientaudio

    16 }

    17 

    18 # This is necessary because both epoc32/include and Phonon contain videoplayer.h.

    19 # By making /epoc32/include the first SYSTEMINCLUDE, we ensure that

    20 # '#include <videoplayer.h>' picks up the Symbian header, as intended.

    21 PREPEND_INCLUDEPATH = /epoc32/include

    22 

    23 INCLUDEPATH += $$MW_LAYER_SYSTEMINCLUDE

    24 

    25 HEADERS +=                                           \

    26            $$PHONON_MMF_DIR/abstractaudioeffect.h    \

    27            $$PHONON_MMF_DIR/abstractmediaplayer.h    \

    28            $$PHONON_MMF_DIR/abstractplayer.h         \

    29            $$PHONON_MMF_DIR/audiooutput.h            \

    30            $$PHONON_MMF_DIR/audioequalizer.h         \

    31            $$PHONON_MMF_DIR/audioplayer.h            \

    32            $$PHONON_MMF_DIR/backend.h                \

    33            $$PHONON_MMF_DIR/bassboost.h              \

    34            $$PHONON_MMF_DIR/defs.h                   \

    35            $$PHONON_MMF_DIR/dummyplayer.h            \

    36            $$PHONON_MMF_DIR/effectfactory.h          \

    37            $$PHONON_MMF_DIR/mmf_medianode.h          \

    38            $$PHONON_MMF_DIR/mediaobject.h            \

    39            $$PHONON_MMF_DIR/utils.h                  \

    40            $$PHONON_MMF_DIR/videooutput.h            \

    41            $$PHONON_MMF_DIR/videooutputobserver.h    \

    42            $$PHONON_MMF_DIR/mmf_videoplayer.h        \

    43            $$PHONON_MMF_DIR/videowidget.h            \

    44            $$PHONON_MMF_DIR/volumeobserver.h

    45 

    46 SOURCES +=                                           \

    47            $$PHONON_MMF_DIR/abstractaudioeffect.cpp  \

    48            $$PHONON_MMF_DIR/abstractmediaplayer.cpp  \

    49            $$PHONON_MMF_DIR/abstractplayer.cpp       \

    50            $$PHONON_MMF_DIR/audiooutput.cpp          \

    51            $$PHONON_MMF_DIR/audioequalizer.cpp       \

    52            $$PHONON_MMF_DIR/audioplayer.cpp          \

    53            $$PHONON_MMF_DIR/backend.cpp              \

    54            $$PHONON_MMF_DIR/bassboost.cpp            \

    55            $$PHONON_MMF_DIR/dummyplayer.cpp          \

    56            $$PHONON_MMF_DIR/effectfactory.cpp        \

    57            $$PHONON_MMF_DIR/mmf_medianode.cpp        \

    58            $$PHONON_MMF_DIR/mediaobject.cpp          \

    59            $$PHONON_MMF_DIR/utils.cpp                \

    60            $$PHONON_MMF_DIR/videooutput.cpp          \

    61            $$PHONON_MMF_DIR/mmf_videoplayer.cpp      \

    62            $$PHONON_MMF_DIR/videowidget.cpp

    63 

    64 debug {

    65     INCLUDEPATH += $$PHONON_MMF_DIR/mmfphonondebug

    66     LIBS += -lphonon_mmf_debug.lib

    67     LIBS += -lhal

    68 }

    69 

    70 LIBS += -lmediaclientvideo  # For CVideoPlayerUtility

    71 LIBS += -lcone              # For CCoeEnv

    72 LIBS += -lws32              # For RWindow

    73 LIBS += -lefsrv             # For file server

    74 LIBS += -lapgrfx -lapmime   # For recognizer

    75 

    76 # These are for effects.

    77 LIBS += -lAudioEqualizerEffect -lBassBoostEffect -lDistanceAttenuationEffect -lDopplerBase -lEffectBase -lEnvironmentalReverbEffect -lListenerDopplerEffect -lListenerLocationEffect -lListenerOrientationEffect -lLocationBase -lLoudnessEffect -lOrientationBase -lSourceDopplerEffect -lSourceLocationEffect -lSourceOrientationEffect -lStereoWideningEffect

    78 

    79 # This is needed for having the .qtplugin file properly created on Symbian.

    80 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/phonon_backend

    81 

    82 target.path = $$[QT_INSTALL_PLUGINS]/phonon_backend

    83 INSTALLS += target

    84 

    85 include(../../../qpluginbase.pri)

    86 

    87 TARGET.UID3=0x2001E629

    88