|
1 TEMPLATE=lib |
|
2 TARGET=QtDesigner |
|
3 QT += xml |
|
4 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols |
|
5 CONFIG += qt |
|
6 win32|mac: CONFIG += debug_and_release |
|
7 DESTDIR = ../../../../lib |
|
8 !wince*:DLLDESTDIR = ../../../../bin |
|
9 |
|
10 isEmpty(QT_MAJOR_VERSION) { |
|
11 VERSION=4.3.0 |
|
12 } else { |
|
13 VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION} |
|
14 } |
|
15 |
|
16 unix:QMAKE_PKGCONFIG_REQUIRES += QtXml |
|
17 |
|
18 include(../../../../src/qt_targets.pri) |
|
19 QMAKE_TARGET_PRODUCT = Designer |
|
20 QMAKE_TARGET_DESCRIPTION = Graphical user interface designer. |
|
21 |
|
22 !contains(CONFIG, static) { |
|
23 CONFIG += dll |
|
24 |
|
25 DEFINES += \ |
|
26 QDESIGNER_SDK_LIBRARY \ |
|
27 QDESIGNER_EXTENSION_LIBRARY \ |
|
28 QDESIGNER_UILIB_LIBRARY \ |
|
29 QDESIGNER_SHARED_LIBRARY |
|
30 } else { |
|
31 DEFINES += QT_DESIGNER_STATIC |
|
32 } |
|
33 |
|
34 #load up the headers info |
|
35 CONFIG += qt_install_headers |
|
36 HEADERS_PRI = $$QT_BUILD_TREE/include/QtDesigner/headers.pri |
|
37 include($$HEADERS_PRI, "", true)|clear(HEADERS_PRI) |
|
38 |
|
39 #mac frameworks |
|
40 mac:CONFIG += explicitlib |
|
41 mac:!static:contains(QT_CONFIG, qt_framework) { |
|
42 QMAKE_FRAMEWORK_BUNDLE_NAME = $$TARGET |
|
43 CONFIG += lib_bundle qt_no_framework_direct_includes qt_framework |
|
44 CONFIG(debug, debug|release) { |
|
45 !build_pass:CONFIG += build_all |
|
46 } else { #release |
|
47 !debug_and_release|build_pass { |
|
48 CONFIG -= qt_install_headers #no need to install these as well |
|
49 FRAMEWORK_HEADERS.version = Versions |
|
50 FRAMEWORK_HEADERS.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES |
|
51 FRAMEWORK_HEADERS.path = Headers |
|
52 } |
|
53 QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS |
|
54 } |
|
55 } |
|
56 |
|
57 include(extension/extension.pri) |
|
58 include(sdk/sdk.pri) |
|
59 include(uilib/uilib.pri) |
|
60 include(shared/shared.pri) |
|
61 PRECOMPILED_HEADER=lib_pch.h |
|
62 |
|
63 include(../sharedcomponents.pri) |
|
64 include(../components/component.pri) |
|
65 |
|
66 target.path=$$[QT_INSTALL_LIBS] |
|
67 INSTALLS += target |
|
68 win32 { |
|
69 dlltarget.path=$$[QT_INSTALL_BINS] |
|
70 INSTALLS += dlltarget |
|
71 } |
|
72 |
|
73 |
|
74 qt_install_headers { |
|
75 designer_headers.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES |
|
76 designer_headers.path = $$[QT_INSTALL_HEADERS]/QtDesigner |
|
77 INSTALLS += designer_headers |
|
78 } |