1 TRANSLATIONS = $$files(*.ts)

     2 

     3 LRELEASE = $$QT_BUILD_TREE/bin/lrelease

     4 LRELEASE ~= s,/,$$QMAKE_DIR_SEP,

     5 

     6 contains(TEMPLATE_PREFIX, vc):vcproj = 1

     7 

     8 TEMPLATE = app

     9 TARGET = qm_phony_target

    10 CONFIG -= qt separate_debug_info

    11 QT =

    12 LIBS =

    13 

    14 updateqm.input = TRANSLATIONS

    15 updateqm.output = ${QMAKE_FILE_BASE}.qm

    16 isEmpty(vcproj):updateqm.variable_out = PRE_TARGETDEPS

    17 updateqm.commands = @echo lrelease ${QMAKE_FILE_IN}; $$LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}

    18 updateqm.name = LRELEASE ${QMAKE_FILE_IN}

    19 updateqm.CONFIG += no_link

    20 QMAKE_EXTRA_COMPILERS += updateqm

    21 

    22 isEmpty(vcproj) {

    23     QMAKE_LINK = @: IGNORE THIS LINE

    24     OBJECTS_DIR =

    25     win32:CONFIG -= embed_manifest_exe

    26 } else {

    27     CONFIG += console

    28     PHONY_DEPS = .

    29     phony_src.input = PHONY_DEPS

    30     phony_src.output = phony.c

    31     phony_src.variable_out = GENERATED_SOURCES

    32     phony_src.commands = echo int main() { return 0; } > phony.c

    33     phony_src.name = CREATE phony.c

    34     phony_src.CONFIG += combine

    35     QMAKE_EXTRA_COMPILERS += phony_src

    36 }

    37 

    38 translations.path = $$[QT_INSTALL_TRANSLATIONS]

    39 translations.files = $$TRANSLATIONS

    40 translations.files ~= s,\\.ts$,.qm,g

    41 translations.CONFIG += no_check_exist

    42 INSTALLS += translations