1 TEMPLATE = app

     2 TARGET = browser

     3 QT += webkit network

     4 

     5 CONFIG += qt warn_on

     6 contains(QT_BUILD_PARTS, tools):!embedded: CONFIG += uitools

     7 else: DEFINES += QT_NO_UITOOLS

     8 

     9 FORMS += \

    10     addbookmarkdialog.ui \

    11     bookmarks.ui \

    12     cookies.ui \

    13     cookiesexceptions.ui \

    14     downloaditem.ui \

    15     downloads.ui \

    16     history.ui \

    17     passworddialog.ui \

    18     proxy.ui \

    19     settings.ui

    20 

    21 HEADERS += \

    22     autosaver.h \

    23     bookmarks.h \

    24     browserapplication.h \

    25     browsermainwindow.h \

    26     chasewidget.h \

    27     cookiejar.h \

    28     downloadmanager.h \

    29     edittableview.h \

    30     edittreeview.h \

    31     history.h \

    32     modelmenu.h \

    33     networkaccessmanager.h \

    34     searchlineedit.h \

    35     settings.h \

    36     squeezelabel.h \

    37     tabwidget.h \

    38     toolbarsearch.h \

    39     urllineedit.h \

    40     webview.h \

    41     xbel.h

    42 

    43 SOURCES += \

    44     autosaver.cpp \

    45     bookmarks.cpp \

    46     browserapplication.cpp \

    47     browsermainwindow.cpp \

    48     chasewidget.cpp \

    49     cookiejar.cpp \

    50     downloadmanager.cpp \

    51     edittableview.cpp \

    52     edittreeview.cpp \

    53     history.cpp \

    54     modelmenu.cpp \

    55     networkaccessmanager.cpp \

    56     searchlineedit.cpp \

    57     settings.cpp \

    58     squeezelabel.cpp \

    59     tabwidget.cpp \

    60     toolbarsearch.cpp \

    61     urllineedit.cpp \

    62     webview.cpp \

    63     xbel.cpp \

    64     main.cpp

    65 

    66 RESOURCES += data/data.qrc htmls/htmls.qrc

    67 

    68 build_all:!build_pass {

    69     CONFIG -= build_all

    70     CONFIG += release

    71 }

    72 

    73 win32 {

    74    RC_FILE = browser.rc

    75 }

    76 

    77 mac {

    78     ICON = browser.icns

    79     QMAKE_INFO_PLIST = Info_mac.plist

    80     TARGET = Browser

    81 

    82     # No 64-bit Flash on Mac, so build the browser 32-bit

    83     contains(QT_CONFIG, x86) {

    84         CONFIG -= x86_64

    85         CONFIG += x86

    86     }

    87     contains(QT_CONFIG, ppc) {

    88         CONFIG -= ppc64

    89         CONFIG += ppc

    90     }

    91 }

    92 

    93 wince*: {

    94     DEPLOYMENT_PLUGIN += qjpeg qgif

    95 }

    96 

    97 # install

    98 target.path = $$[QT_INSTALL_DEMOS]/browser

    99 sources.files = $$SOURCES $$HEADERS $$RESOURCES $$FORMS *.plist *.icns *.ico *.rc *.pro *.html *.doc images htmls data

   100 sources.path = $$[QT_INSTALL_DEMOS]/browser

   101 INSTALLS += target sources

   102 

   103 symbian {

   104     TARGET.UID3 = 0xA000CF70

   105     include($$QT_SOURCE_TREE/demos/symbianpkgrules.pri)

   106 }