1 # Additional Qt project file for qtmain lib on Symbian

     2 TEMPLATE = lib

     3 TARGET	 = qtmain

     4 DESTDIR	 = $$QMAKE_LIBDIR_QT

     5 QT       =

     6 

     7 CONFIG	+= staticlib warn_on

     8 CONFIG	-= qt shared

     9 

    10 symbian {

    11     # Note: UID only needed for ensuring that no filename generation conflicts occur

    12     TARGET.UID3 = 0x2001E61F

    13     CONFIG      +=  png zlib

    14     CONFIG	-=  jpeg

    15     INCLUDEPATH	+=  tmp $$QMAKE_INCDIR_QT/QtCore $$MW_LAYER_SYSTEMINCLUDE

    16     SOURCES	 =  qts60main.cpp \

    17                     qts60main_mcrt0.cpp

    18 

    19     # s60main needs to be built in ARM mode for GCCE to work.

    20     MMP_RULES+="ALWAYS_BUILD_AS_ARM"

    21 

    22     # staticlib should not have any lib depencies in s60

    23     # This seems not to work, some hard coded libs are still added as dependency

    24     LIBS =

    25 

    26     # Workaround for abld toolchain problem to make ARMV6 qtmain.lib link with GCCE apps

    27     symbian-abld: QMAKE_CXXFLAGS.ARMCC += --dllimport_runtime

    28 } else {

    29     error("$$_FILE_ is intended only for Symbian!")

    30 }

    31 

    32 include(../qbase.pri)