--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/mkspecs/features/win32/qaxcontainer.prf	Mon Jan 11 14:00:40 2010 +0000
@@ -0,0 +1,34 @@
+!debug_and_release|build_pass {
+   CONFIG(debug, debug|release) {
+      LIBS += -lQAxContainerd
+   } else { 
+      LIBS += -lQAxContainer
+   }
+} else {
+   LIBS += -lQAxContainer
+}
+
+isEmpty(QMAKE_DUMPCPP) {
+    win32:QMAKE_DUMPCPP = $$[QT_INSTALL_BINS]\dumpcpp.exe
+}
+
+dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
+qaxcontainer_compat: dumpcpp_decl.commands += -compat
+dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
+dumpcpp_decl.input = TYPELIBS
+dumpcpp_decl.variable_out = HEADERS
+dumpcpp_decl.name = DUMP
+dumpcpp_decl.CONFIG += no_link
+dumpcpp_decl.depends = $$QMAKE_DUMPCPP
+
+QMAKE_EXTRA_COMPILERS += dumpcpp_decl
+
+
+dumpcpp_impl.commands = $$QMAKE_DUMPCPP -donothing
+dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
+dumpcpp_impl.input = TYPELIBS
+dumpcpp_impl.variable_out = SOURCES
+dumpcpp_impl.name = CPP
+dumpcpp_impl.depends = $$QMAKE_DUMPCPP ${QMAKE_FILE_BASE}.h
+
+QMAKE_EXTRA_COMPILERS += dumpcpp_impl