tests/auto/qfile/test/test.pro
author Alex Gilkes <alex.gilkes@nokia.com>
Mon, 11 Jan 2010 14:00:40 +0000
changeset 0 1918ee327afb
child 3 41300fa6a67c
permissions -rw-r--r--
Revision: 200952

load(qttest_p4)
SOURCES  += ../tst_qfile.cpp

wince*|symbian {
    QT = core gui
    files.sources += ..\dosfile.txt ..\noendofline.txt ..\testfile.txt \
                     ..\testlog.txt ..\two.dots.file ..\tst_qfile.cpp \
                     ..\Makefile ..\forCopying.txt ..\forRenaming.txt
    files.path = .
    resour.sources += ..\resources\file1.ext1
    resour.path = resources

    DEPLOYMENT = files resour
}

wince* {
    DEFINES += SRCDIR=\\\"\\\"
} else:symbian {
    # do not define SRCDIR at all
    TARGET.EPOCHEAPSIZE = 0x100000 0x3000000
} else {
    QT = core network
    DEFINES += SRCDIR=\\\"$$PWD/../\\\"
}

RESOURCES      += ../qfile.qrc ../rename-fallback.qrc ../copy-fallback.qrc

TARGET = ../tst_qfile

win32 {
    CONFIG(debug, debug|release) {
        TARGET = ../../debug/tst_qfile
    } else {
        TARGET = ../../release/tst_qfile
    }
    LIBS+=-lole32 -luuid
}