1 ######################################################################

     2 #

     3 # Mobility API project - multimedia 

     4 #

     5 ######################################################################

     6 

     7 TEMPLATE = subdirs

     8 

     9 SUBDIRS += m3u

    10 

    11 win32:!wince* {

    12     win32-msvc2005|win32-msvc2008: SUBDIRS *= directshow wmp

    13 }

    14 

    15 unix:!mac:!symbian {

    16     TMP_GST_LIBS = \

    17         gstreamer-0.10 >= 0.10.19 \

    18         gstreamer-base-0.10 >= 0.10.19 \

    19         gstreamer-interfaces-0.10 >= 0.10.19 \

    20         gstreamer-audio-0.10 >= 0.10.19 \

    21         gstreamer-video-0.10 >= 0.10.19

    22 

    23     system(pkg-config --exists \'$${TMP_GST_LIBS}\' --print-errors): {

    24         SUBDIRS += gstreamer

    25     } else {

    26         contains(QT_CONFIG, multimedia): SUBDIRS += audiocapture

    27     }

    28    

    29     system(pkg-config --exists \'libpulse >= 0.9.14\'):SUBDIRS += pulseaudio

    30 

    31     SUBDIRS += v4l

    32 }

    33 

    34 mac {

    35     contains(QT_CONFIG, phonon): SUBDIRS += phonon

    36     contains(QT_CONFIG, multimedia): SUBDIRS += audiocapture

    37 }

    38 

    39 symbian:SUBDIRS += symbian