|
1 # Qt bearer management library |
|
2 TEMPLATE = lib |
|
3 TARGET = QtBearer |
|
4 |
|
5 QT += network |
|
6 include (../../common.pri) |
|
7 |
|
8 DEFINES += QT_BUILD_BEARER_LIB QT_MAKEDLL |
|
9 |
|
10 #DEFINES += BEARER_MANAGEMENT_DEBUG |
|
11 |
|
12 PUBLIC_HEADERS += qnetworkconfiguration.h \ |
|
13 qnetworksession.h \ |
|
14 qnetworkconfigmanager.h |
|
15 |
|
16 HEADERS += $$PUBLIC_HEADERS |
|
17 SOURCES += qnetworksession.cpp \ |
|
18 qnetworkconfigmanager.cpp \ |
|
19 qnetworkconfiguration.cpp |
|
20 |
|
21 symbian: { |
|
22 contains(snap_enabled, yes) { |
|
23 message("Building with SNAP support") |
|
24 DEFINES += SNAP_FUNCTIONALITY_AVAILABLE=1 |
|
25 LIBS += -lcmmanager |
|
26 } else { |
|
27 message("Building without SNAP support") |
|
28 LIBS += -lapengine |
|
29 } |
|
30 |
|
31 INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE |
|
32 |
|
33 HEADERS += qnetworkconfigmanager_s60_p.h \ |
|
34 qnetworkconfiguration_s60_p.h \ |
|
35 qnetworksession_s60_p.h |
|
36 SOURCES += qnetworkconfigmanager_s60_p.cpp \ |
|
37 qnetworkconfiguration_s60_p.cpp \ |
|
38 qnetworksession_s60_p.cpp |
|
39 |
|
40 LIBS += -lcommdb \ |
|
41 -lapsettingshandlerui \ |
|
42 -lconnmon \ |
|
43 -lcentralrepository \ |
|
44 -lesock \ |
|
45 -linsock \ |
|
46 -lecom \ |
|
47 -lefsrv \ |
|
48 -lnetmeta |
|
49 |
|
50 TARGET.CAPABILITY = ALL -TCB |
|
51 TARGET.UID3 = 0x2002AC81 |
|
52 |
|
53 QtBearerManagement.sources = QtBearer.dll |
|
54 QtBearerManagement.path = /sys/bin |
|
55 DEPLOYMENT += QtBearerManagement |
|
56 } else { |
|
57 maemo6 { |
|
58 CONFIG += link_pkgconfig |
|
59 |
|
60 exists(../debug) { |
|
61 message("Enabling debug messages.") |
|
62 DEFINES += BEARER_MANAGEMENT_DEBUG |
|
63 } |
|
64 |
|
65 HEADERS += qnetworksession_maemo_p.h \ |
|
66 qnetworkconfigmanager_maemo_p.h \ |
|
67 qnetworkconfiguration_maemo_p.h |
|
68 |
|
69 SOURCES += qnetworkconfigmanager_maemo.cpp \ |
|
70 qnetworksession_maemo.cpp |
|
71 |
|
72 documentation.path = $$QT_MOBILITY_PREFIX/doc |
|
73 documentation.files = doc/html |
|
74 |
|
75 PKGCONFIG += glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet |
|
76 |
|
77 CONFIG += create_pc create_prl |
|
78 QMAKE_PKGCONFIG_REQUIRES = glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet |
|
79 pkgconfig.path = $$QT_MOBILITY_LIB/pkgconfig |
|
80 pkgconfig.files = QtBearer.pc |
|
81 |
|
82 INSTALLS += pkgconfig documentation |
|
83 |
|
84 } else { |
|
85 |
|
86 DEFINES += BEARER_ENGINE |
|
87 |
|
88 HEADERS += qnetworkconfigmanager_p.h \ |
|
89 qnetworkconfiguration_p.h \ |
|
90 qnetworksession_p.h \ |
|
91 qnetworksessionengine_p.h \ |
|
92 qgenericengine_p.h |
|
93 |
|
94 SOURCES += qnetworkconfigmanager_p.cpp \ |
|
95 qnetworksession_p.cpp \ |
|
96 qnetworksessionengine.cpp \ |
|
97 qgenericengine.cpp |
|
98 |
|
99 unix:!mac:contains(networkmanager_enabled, yes) { |
|
100 contains(QT_CONFIG,dbus) { |
|
101 DEFINES += BACKEND_NM |
|
102 QT += dbus |
|
103 |
|
104 HEADERS += qnmdbushelper_p.h \ |
|
105 qnetworkmanagerservice_p.h \ |
|
106 qnmwifiengine_unix_p.h |
|
107 |
|
108 SOURCES += qnmdbushelper.cpp \ |
|
109 qnetworkmanagerservice_p.cpp \ |
|
110 qnmwifiengine_unix.cpp |
|
111 } else { |
|
112 message("NetworkManager backend requires Qt DBus support") |
|
113 } |
|
114 } |
|
115 |
|
116 win32: { |
|
117 HEADERS += qnlaengine_win_p.h \ |
|
118 qnetworksessionengine_win_p.h |
|
119 |
|
120 !wince*:HEADERS += qnativewifiengine_win_p.h |
|
121 |
|
122 SOURCES += qnlaengine_win.cpp |
|
123 |
|
124 !wince*:SOURCES += qnativewifiengine_win.cpp |
|
125 |
|
126 !wince*:LIBS += -lWs2_32 |
|
127 wince*:LIBS += -lWs2 |
|
128 } |
|
129 } |
|
130 macx: { |
|
131 HEADERS += qcorewlanengine_mac_p.h |
|
132 SOURCES+= qcorewlanengine_mac.mm |
|
133 LIBS += -framework Foundation -framework SystemConfiguration |
|
134 |
|
135 contains(corewlan_enabled, yes) { |
|
136 isEmpty(QMAKE_MAC_SDK) { |
|
137 SDK6="yes" |
|
138 } else { |
|
139 contains(QMAKE_MAC_SDK, "/Developer/SDKs/MacOSX10.6.sdk") { |
|
140 SDK6="yes" |
|
141 } |
|
142 } |
|
143 |
|
144 !isEmpty(SDK6) { |
|
145 LIBS += -framework CoreWLAN |
|
146 DEFINES += MAC_SDK_10_6 |
|
147 } |
|
148 } |
|
149 |
|
150 |
|
151 } |
|
152 } |
|
153 |
|
154 CONFIG += middleware |
|
155 include(../../features/deploy.pri) |