1 TEMPLATE = lib

     2 TARGET = QtPublishSubscribe

     3 QT = core

     4 

     5 include(../../common.pri)

     6 

     7 DEFINES += QT_BUILD_CFW_LIB QT_MAKEDLL

     8 

     9 

    10 PUBLIC_HEADERS += \

    11            qvaluespace.h \

    12            qvaluespacepublisher.h \

    13            qvaluespacesubscriber.h

    14 

    15 PRIVATE_HEADERS += \

    16            qvaluespace_p.h \

    17            qvaluespacemanager_p.h

    18 

    19 HEADERS += $$PUBLIC_HEADERS $$PRIVATE_HEADERS

    20 

    21 SOURCES += \

    22            qvaluespace.cpp \

    23            qvaluespacemanager.cpp \

    24            qvaluespacepublisher.cpp \

    25            qvaluespacesubscriber.cpp

    26 

    27 symbian {

    28     DEPENDPATH += xqsettingsmanager_symbian

    29     INCLUDEPATH += xqsettingsmanager_symbian

    30     DEFINES += XQSETTINGSMANAGER_NO_LIBRARY

    31     DEFINES += XQSETTINGSMANAGER_NO_TRANSACTIONS

    32     DEFINES += XQSETTINGSMANAGER_NO_CENREPKEY_CREATION_DELETION

    33     include(xqsettingsmanager_symbian/settingsmanager.pri)

    34 

    35     DEPENDPATH += psmapperserver_symbian

    36     INCLUDEPATH += psmapperserver_symbian \

    37                $${EPOCROOT}epoc32\include\platform

    38 

    39     HEADERS += pathmapper_symbian_p.h \

    40         pathmapper_proxy_symbian_p.h

    41     LIBS += -lefsrv

    42 

    43     DEFINES += QT_BUILD_INTERNAL

    44     HEADERS += settingslayer_symbian_p.h

    45     SOURCES += settingslayer_symbian.cpp

    46 

    47     TARGET.CAPABILITY = ALL -TCB

    48     TARGET.UID3 = 0x2002AC78

    49 

    50     QtPublishSubscribeDeployment.sources = QtPublishSubscribe.dll qpspathmapperserver.exe

    51     QtPublishSubscribeDeployment.path = /sys/bin

    52     DEPLOYMENT += QtPublishSubscribeDeployment

    53 }

    54 

    55 unix:!symbian {

    56     maemo6 {

    57         SOURCES += contextkitlayer.cpp

    58         CONFIG += link_pkgconfig

    59         PKGCONFIG += contextsubscriber-1.0 QtDBus

    60     } else {

    61         QT += network

    62 

    63         !mac:maemo5 { 

    64             HEADERS += gconflayer_linux_p.h

    65             SOURCES += gconflayer_linux.cpp

    66 

    67             #As a workaround build GConfItem wrapper class with the project

    68             HEADERS += gconfitem_p.h

    69             SOURCES += gconfitem.cpp

    70 

    71             CONFIG += link_pkgconfig

    72             PKGCONFIG += glib-2.0 gconf-2.0

    73         }

    74 

    75         !maemo5 {

    76             #do not use shared memory layer on Maemo5

    77             HEADERS += qsystemreadwritelock_p.h \

    78                        qmallocpool_p.h \

    79                        qpacketprotocol_p.h

    80             SOURCES += sharedmemorylayer.cpp \

    81                        qmallocpool.cpp \

    82                        qsystemreadwritelock_unix.cpp \

    83                        qpacketprotocol.cpp

    84         }

    85     }

    86 }

    87 

    88 win32 {

    89     HEADERS += qsystemreadwritelock_p.h

    90     SOURCES += \

    91                qsystemreadwritelock_win.cpp \

    92                registrylayer_win.cpp

    93 

    94     !wince*:LIBS += -ladvapi32

    95     wince*:LIBS += -ltoolhelp

    96 }

    97 

    98 CONFIG += middleware

    99 include(../../features/deploy.pri)