diff -r 000000000000 -r 876b1a06bc25 plugins/multimedia/multimedia.pro
--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/plugins/multimedia/multimedia.pro	Wed Aug 25 15:49:42 2010 +0300
@@ -0,0 +1,42 @@
+######################################################################
+#
+# Mobility API project - multimedia 
+#
+######################################################################
+
+TEMPLATE = subdirs
+
+include (../../staticconfig.pri)
+
+SUBDIRS += m3u
+
+win32 {
+    SUBDIRS += audiocapture
+}
+
+win32:!wince* {
+    contains(directshow_enabled, yes): SUBDIRS += directshow
+    contains(wmp_enabled, yes): SUBDIRS += wmp
+}
+
+unix:!mac:!symbian {
+    TMP_GST_LIBS = \
+        gstreamer-0.10 >= 0.10.19 \
+        gstreamer-base-0.10 >= 0.10.19 \
+        gstreamer-interfaces-0.10 >= 0.10.19 \
+        gstreamer-audio-0.10 >= 0.10.19 \
+        gstreamer-video-0.10 >= 0.10.19
+
+    system(pkg-config --exists \'$${TMP_GST_LIBS}\' --print-errors): {
+        SUBDIRS += gstreamer
+    } else {
+        SUBDIRS += audiocapture
+    }
+    SUBDIRS += v4l
+}
+
+mac {
+    SUBDIRS += audiocapture qt7
+}
+
+symbian:SUBDIRS += symbian