1 %option case-insensitive

     2 %option noyywrap

     3 %option 8bit

     4 %option stack

     5 %s mediaquery

     6 

     7 h               [0-9a-fA-F]

     8 nonascii        [\200-\377]

     9 unicode         \\{h}{1,6}[ \t\r\n\f]?

    10 escape          {unicode}|\\[ -~\200-\377]

    11 nmstart         [_a-zA-Z]|{nonascii}|{escape}

    12 nmchar          [_a-zA-Z0-9-]|{nonascii}|{escape}

    13 string1         \"([\t !#$%&(-~]|\\{nl}|\'|{nonascii}|{escape})*\"

    14 string2         \'([\t !#$%&(-~]|\\{nl}|\"|{nonascii}|{escape})*\'

    15 hexcolor        {h}{3}|{h}{6}

    16 

    17 ident           -?{nmstart}{nmchar}*

    18 name            {nmchar}+

    19 num             [0-9]+|[0-9]*"."[0-9]+

    20 intnum          [0-9]+

    21 string          {string1}|{string2}

    22 url             ([!#$%&*-~]|{nonascii}|{escape})*

    23 w               [ \t\r\n\f]*

    24 nl              \n|\r\n|\r|\f

    25 range           \?{1,6}|{h}(\?{0,5}|{h}(\?{0,4}|{h}(\?{0,3}|{h}(\?{0,2}|{h}(\??|{h})))))

    26 

    27 %%

    28 

    29 \/\*[^*]*\*+([^/*][^*]*\*+)*\/  /* ignore comments */

    30 

    31 [ \t\r\n\f]+            {yyTok = WHITESPACE; return yyTok;}

    32 

    33 "<!--"                  {yyTok = SGML_CD; return yyTok;}

    34 "-->"                   {yyTok = SGML_CD; return yyTok;}

    35 "~="                    {yyTok = INCLUDES; return yyTok;}

    36 "|="                    {yyTok = DASHMATCH; return yyTok;}

    37 "^="                    {yyTok = BEGINSWITH; return yyTok;}

    38 "$="                    {yyTok = ENDSWITH; return yyTok;}

    39 "*="                    {yyTok = CONTAINS; return yyTok;}

    40 <mediaquery>"not"       {yyTok = MEDIA_NOT; return yyTok;}

    41 <mediaquery>"only"      {yyTok = MEDIA_ONLY; return yyTok;}

    42 <mediaquery>"and"       {yyTok = MEDIA_AND; return yyTok;}

    43 

    44 {string}                {yyTok = STRING; return yyTok;}

    45 

    46 {ident}                 {yyTok = IDENT; return yyTok;}

    47 

    48 "#"{hexcolor}           {yyTok = HEX; return yyTok;}

    49 "#"{ident}              {yyTok = IDSEL; return yyTok;}

    50 

    51 "@import"               {BEGIN(mediaquery); yyTok = IMPORT_SYM; return yyTok;}

    52 "@page"                 {yyTok = PAGE_SYM; return yyTok;}

    53 "@media"                {BEGIN(mediaquery); yyTok = MEDIA_SYM; return yyTok;}

    54 "@font-face"            {yyTok = FONT_FACE_SYM; return yyTok;}

    55 "@charset"              {yyTok = CHARSET_SYM; return yyTok;}

    56 "@namespace"            {yyTok = NAMESPACE_SYM; return yyTok; }

    57 "@-webkit-rule"         {yyTok = WEBKIT_RULE_SYM; return yyTok; }

    58 "@-webkit-decls"        {yyTok = WEBKIT_DECLS_SYM; return yyTok; }

    59 "@-webkit-value"        {yyTok = WEBKIT_VALUE_SYM; return yyTok; }

    60 "@-webkit-mediaquery"   {BEGIN(mediaquery); yyTok = WEBKIT_MEDIAQUERY_SYM; return yyTok; }

    61 

    62 "!"{w}"important"       {yyTok = IMPORTANT_SYM; return yyTok;}

    63 

    64 {num}em                 {yyTok = EMS; return yyTok;}

    65 {num}__qem              {yyTok = QEMS; return yyTok;} /* quirky ems */

    66 {num}ex                 {yyTok = EXS; return yyTok;}

    67 {num}px                 {yyTok = PXS; return yyTok;}

    68 {num}cm                 {yyTok = CMS; return yyTok;}

    69 {num}mm                 {yyTok = MMS; return yyTok;}

    70 {num}in                 {yyTok = INS; return yyTok;}

    71 {num}pt                 {yyTok = PTS; return yyTok;}

    72 {num}pc                 {yyTok = PCS; return yyTok;}

    73 {num}deg                {yyTok = DEGS; return yyTok;}

    74 {num}rad                {yyTok = RADS; return yyTok;}

    75 {num}grad               {yyTok = GRADS; return yyTok;}

    76 {num}ms                 {yyTok = MSECS; return yyTok;}

    77 {num}s                  {yyTok = SECS; return yyTok;}

    78 {num}Hz                 {yyTok = HERZ; return yyTok;}

    79 {num}kHz                {yyTok = KHERZ; return yyTok;}

    80 {num}{ident}            {yyTok = DIMEN; return yyTok;}

    81 {num}%+                 {yyTok = PERCENTAGE; return yyTok;}

    82 {intnum}                {yyTok = INTEGER; return yyTok;}

    83 {num}                   {yyTok = FLOATTOKEN; return yyTok;}

    84 

    85 "not("                  {yyTok = NOTFUNCTION; return yyTok;}

    86 "url("{w}{string}{w}")" {yyTok = URI; return yyTok;}

    87 "url("{w}{url}{w}")"    {yyTok = URI; return yyTok;}

    88 {ident}"("              {yyTok = FUNCTION; return yyTok;}

    89 

    90 U\+{range}              {yyTok = UNICODERANGE; return yyTok;}

    91 U\+{h}{1,6}-{h}{1,6}    {yyTok = UNICODERANGE; return yyTok;}

    92 

    93 <mediaquery>"{"         |

    94 <mediaquery>";"         {BEGIN(INITIAL); yyTok = *yytext; return yyTok; }

    95 .                       {yyTok = *yytext; return yyTok;}

    96 

    97 %%