<?xml version="1.0"?>

 <xsl:stylesheet  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:doc="tooldoc"  xmlns="http://www.w3.org/2000/svg"  xmlns:s="http://www.w3.org/2000/svg" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:exslt="http://exslt.org/common" xmlns:m="http://exslt.org/math" exclude-result-prefixes="doc s m exslt" >

	  <xsl:key name="color" match="legend/cbox" use="@value"/>

	  <xsl:key name="color-value" match="component" use="@ts"/>

	  <xsl:key name="lgrp-bottom" match="layer-group" use="@from"/>

	  <xsl:key name="lgrp-top" match="layer-group" use="@to"/>

	  <xsl:key name="layer" match="layer" use="@name"/>

	  <xsl:key name="ldg-use" match="group" use="@style-id"/>

	  <xsl:key name="styled" match="group|group/*" use="@style-id"/>	  

	<xsl:output method="xml" cdata-section-elements="script s:script" indent="yes"/>

<xsl:param name="Use-as-name" doc:desc="The attribute to use as the item name. Falls back to 'name'" select="'long-name'"/>

<xsl:param name="Base" doc:desc="The base URL for hyperlinks." select="/SystemDefinition/systemModel/@link"/>

<xsl:param name="Page-width" select="/SystemDefinition/systemModel/@page-width" doc:desc="The width (specify units) of the page. This overrrides the values specified in the model. The model will automatically adjust from landspace to portrait if its dimensions are more appropriate to portrait."/>

<xsl:param name="Detail" doc:desc="The level of detail to show in the diagram. Value is the name of the lowest element to show. If the Static parameter is set to false, mousing-over an item will show its detailed content. by default this is 'component'">

<xsl:choose>

	<xsl:when test="/SystemDefinition/systemModel/@detail"><xsl:value-of select="/SystemDefinition/systemModel/@detail"/></xsl:when>

	<xsl:otherwise>component</xsl:otherwise>

</xsl:choose>

</xsl:param>

<xsl:variable name="pre-Static"><xsl:choose><xsl:when test="/SystemDefinition/systemModel/@static='true'">1</xsl:when><xsl:otherwise>0</xsl:otherwise></xsl:choose></xsl:variable>

<xsl:param name="Static" doc:desc="Set to '1' to get no mouseover or animation efffects" select="$pre-Static='1'"/>

<!-- ====== Constants ============= -->

<xsl:variable name="groupDx" select="number('2.1')"/> <!-- the horizontal distance between groups (mm) -->

<xsl:variable name="groupDy" select="number('3.2')"/> <!-- the vertical distance between groups (mm) -->

<xsl:variable name="cSize" select="number('9.3')"/> <!-- the width and height of a component (mm) -->

<xsl:variable name="mSize" select="number('15.6')"/> <!-- the height and minimum width of a collection (mm) -->

<xsl:variable name="inlineLabel" select="3 * $cSize"/> <!-- the max width of an inline label. 3 time width of a collection. I don't like this. Should compute somehow and make local variable -->

<xsl:variable name="detail-block-space" select="6"/>

<xsl:variable name="legendDx" select="number('5')"/><!-- the horizontal distance between items in a legend (mm) -->

<xsl:variable name="lgrpDx" select="number('5')"/> <!-- the width of a layer group border (mm)-->

<xsl:variable name="lgrpLabelDx" select="number('15')"/> <!-- the width of a layer group title (mm) -->

<xsl:variable name="large-width" select="500"/> <!-- cutoff width to be considered a wide model and thus need larger title size -->

<!-- ====== Computed values ============= -->

	<!-- Space separated ordered list of version numbers. Not all need be valid. Used to determine if a component is deprecated or not -->

<xsl:variable name="Versions">

	<xsl:choose>

		<xsl:when test="/*/systemModel/@version-list"><xsl:value-of select="/*/systemModel/@version-list"/></xsl:when>

		<xsl:otherwise>ER5 ER5U 6.0 6.1 6.2 7.0 7.0s 8.0 8.0a 8.0b 8.1 8.1a 8.1b 9.0 9.1 9.2 9.3 9.4 9.5 9.6 Future</xsl:otherwise>

	</xsl:choose>

</xsl:variable>

 <!-- the full horizontal width of a layer (mm). This is computed from the width of the widest layer, and SHOULD have a min value of 388.5 -->

<xsl:variable name="full-width"><!-- the width  of the model -->

	<xsl:call-template name="max-from-list">

		<xsl:with-param name="list">

			<xsl:for-each select="//layer">

				<xsl:variable name="span-width"> <!-- space taken up by spanning layers-->

					<xsl:call-template name="sum-list">

						<xsl:with-param name="list">0 <xsl:for-each select="following-sibling::layer">

							<xsl:if test="@span and position() - @span &lt;= 0"><xsl:apply-templates select="." mode="min-width"/><xsl:value-of select="concat(' ',$groupDx,' ')"/></xsl:if></xsl:for-each>

						</xsl:with-param> 

					</xsl:call-template>

				</xsl:variable>	

				<xsl:variable name="w"><xsl:apply-templates select="." mode="min-width"/></xsl:variable><!-- the width of the content -->

				<xsl:value-of select="concat($span-width + $w,' ')"/>

			</xsl:for-each>

		</xsl:with-param>

	</xsl:call-template>

</xsl:variable>

<xsl:variable name="right-borders">

	<xsl:call-template name="max-from-list">

		<xsl:with-param name="list">

			<xsl:text>0 </xsl:text>

			<xsl:for-each select="//systemModel/layer-group">

				<xsl:apply-templates select="." mode="right-border"/><xsl:text> </xsl:text>

			</xsl:for-each>

		</xsl:with-param>

	</xsl:call-template>

</xsl:variable>

<xsl:variable name="left-borders">

	<xsl:call-template name="max-from-list">

		<xsl:with-param name="list">

			<xsl:text>0 </xsl:text>

			<xsl:for-each select="//systemModel/layer-group">

				<xsl:apply-templates select="." mode="left-border"/><xsl:text> </xsl:text>

			</xsl:for-each>

		</xsl:with-param>

	</xsl:call-template>

</xsl:variable>

<xsl:variable name="view-width" select="$full-width +  12.8 +  2 * $groupDy + $left-borders + $right-borders"/><!-- the horizontal width of the page in pixels,including empty margins -->

<!-- ==================== draw ==================== -->

<!-- well known patterns -->

<xsl:template name="default-new-pattern">

	<radialGradient id="Patternradial-grad"  gradientUnits="userSpaceOnUse"  cx="10" cy="10" r="14">

		<stop offset="0%" stop-color="white" stop-opacity="1"/>

		<stop offset="100%" stop-opacity="0" stop-color="white" />

	</radialGradient>

</xsl:template>

<xsl:template name="default-ref-pattern"> 	<!-- diagonal line pattern -->

	<linearGradient id="Patternstriped-diag-up" spreadMethod="repeat" gradientUnits="userSpaceOnUse" x1="0%" x2="15%" y1="0%" y2="15%">

		<stop offset="0%" stop-opacity="0" stop-color="white" />

		<stop offset="20%" stop-color="#ccc" stop-opacity="1" />

		<stop offset="40%" stop-opacity="0" stop-color="white" />

		<stop offset="100%" stop-opacity="0" stop-color="white" />

	</linearGradient>

</xsl:template>

<xsl:template name="default-X-pattern"> 	<!-- big dark X -->

	<pattern id="Patternbig-X" patternUnits="userSpaceOnUse" x="0" y="0" width="100%" height="100%" viewBox="0 0 10 10">

		<path d="M 1 1 L 9 9 M 1 9  L 9 1" stroke="#555" stroke-width="1.15" stroke-linecap="round"/>

	</pattern> 

</xsl:template>

<!-- well-known border shapes -->

<xsl:template name="default-box-border">

    <symbol id="Borderbox" viewBox="0 0 20 20">

      <path d="M 0 0 L 0 20 L 20 20 L 20 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-clipLB-border">

    <symbol id="Borderbox-clipLB" viewBox="0 0 20 20">

      <path d="M 0 0 L 0 15 L 5 20 L 20 20 L 20 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-clipLT-border">

    <symbol id="Borderbox-clipLT" viewBox="0 0 20 20">

      <path d="M 5 0 L 0 5 L 0 20 L 20 20 L 20 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-clipRB-border">

    <symbol id="Borderbox-clipRB" viewBox="0 0 20 20">

      <path d="M 0 0 L 0 20 L 15 20 L 20 15 L 20 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-clipRT-border">

    <symbol id="Borderbox-clipRT" viewBox="0 0 20 20">

      <path d="M 0 0 L 0 20 L 20 20 L 20 5 L 15 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-clipAll-border">

    <symbol id="Borderbox-clipAll" viewBox="0 0 20 20">

      <path d="M 5 0 L 0 5 L 0 15 L 5 20 L 15 20 L 20 15 L 20 5 L 15 0 z" stroke="black"/>

    </symbol>

</xsl:template>

<xsl:template name="default-round-border">

	<symbol id="Borderround" viewBox="0 0 20 20">

		<circle cx="10" cy="10" r="10" stroke="black" />

	</symbol>

</xsl:template>

<xsl:template name="default-hexagon-border">

	<symbol id="Borderhexagon" viewBox="0 0 20 20">

		<path d="M 0 10 L 5.8 0 L 14.2 0 L 20 10 L 14.2 20 L 5.8 20 z" stroke="black" />

	</symbol>

</xsl:template>

<!-- end borders -->

		<!-- overridden by output of shapes.xsl -->

<xsl:template match="SystemDefinition" mode="shapes">

	<xsl:call-template name="default-new-pattern"/>

	<xsl:call-template name="default-ref-pattern"/>

	<xsl:call-template name="default-X-pattern"/> 

		<!-- borders to use for OSD components -->

	<xsl:call-template name="default-box-border"/>

	<xsl:call-template name="default-clipLB-border"/>

	<xsl:call-template name="default-clipLT-border"/>

	<xsl:call-template name="default-clipRB-border"/>

	<xsl:call-template name="default-clipRT-border"/>

	<xsl:call-template name="default-clipAll-border"/>

</xsl:template>

<xsl:template match="*" mode="filter"/> <!-- filters for all items -->

<xsl:template match="*" mode="text-filter"/> <!-- fitler for just text -->

<xsl:template match="/SystemDefinition">

<xsl:if test="systemModel/@resolution"><xsl:processing-instruction name="AdobeSVGViewer">resolution="<xsl:value-of select="systemModel/@resolution"/>"</xsl:processing-instruction></xsl:if>

<svg  version="1.1" onload="wrapalltext()">

	<xsl:attribute name="class">

		<xsl:value-of select="$Detail"/>

		<xsl:if test="/SystemDefinition/systemModel/@detail-type">-<xsl:value-of select="/SystemDefinition/systemModel/@detail-type"/></xsl:if>

	</xsl:attribute>

	<xsl:copy-of select="@xml:lang"/> <!-- localized language -->

	<xsl:variable name="page-height">

		<xsl:call-template name="sum-list">

			<xsl:with-param name="list">

				<xsl:value-of select="concat($groupDy,' ')"/>

				<xsl:for-each select="systemModel/layer[not(@span)] | systemModel/legend-layer">

					<xsl:apply-templates select="." mode="height"/>

					<xsl:value-of select="concat(' ',$groupDy + $lgrpDx * (count(key('lgrp-top',@name)) +  count(key('lgrp-bottom',@name))),' ')"/>

				</xsl:for-each>

			</xsl:with-param>

		</xsl:call-template>

	</xsl:variable>

		 <!-- has groupDy margin around all edges -->

	<xsl:attribute name="viewBox"><xsl:value-of select="concat(-$groupDy - $left-borders ,' 0 ',$view-width ,' ', $page-height)"/></xsl:attribute>

	<xsl:if test="$Page-width!=''">

		<xsl:attribute name="width"><xsl:value-of select="$Page-width"/></xsl:attribute>

		<xsl:variable name="unit" select="translate($Page-width,'0123456789-.','')"/>

		<xsl:attribute name="height">

			<xsl:choose>

				<xsl:when test="$page-height &gt; ($view-width *  297 div 210)"><xsl:value-of select="297 * number(substring-before($Page-width,$unit)) div 210"/></xsl:when>

				<xsl:otherwise><xsl:value-of select="210 * number(substring-before($Page-width,$unit)) div 297"/></xsl:otherwise>

			</xsl:choose>

		<xsl:value-of select="$unit"/></xsl:attribute>

	</xsl:if>

	<xsl:apply-templates select="systemModel" mode="title"/>

	<defs>

    <style type="text/css">

    text.layer, text.block, text.subblock, text.collection, text.component,

    text.cbox, text.lgrp, text.label, text.lgd {

		fill:black;

		font-family: <xsl:call-template name="default-font"/>;

    }

    text.title {

		fill:red;

		font-weight: bold;

		font-size: <xsl:call-template name="title-line-height"/>px;	

		font-family: <xsl:call-template name="default-font"/>;

    }    

    text.component {		

		font-size: 1.940px;  /*  5.5pt  */

		font-weight: bold

	}

 	text.lgd, 

	text.layer, text.block {

		font-size: 4.233px;  /*  12pt  */

		font-weight: bold;

	}

	text.label {		

		font-size: 1.940px;  /*  5.5pt  */

		font-weight: bold

	}

	text.cbox {		

		font-size: 1.411px;  /*  4pt  */

		font-weight: bold

	}

	text.lgrp {

		font-size: 12.699px;  /*  36pt  */

		font-weight: normal;

	}

<!-- block font sizes -->

svg.subblock text.block,

svg.subblock-fixed text.block {

		font-size: 7.7605px;  /*  22pt  */

	}

svg.block text.block,

svg.block-fixed text.block {

		font-size: 11.288px;  /*  32pt  */

		font-weight: normal;

	}

svg.subblock-fixed text.block, 

svg.block-fixed text.block {

	}

<!-- subblock font sizes -->

	text.subblock {

		font-size: 2.822px;  /*  8pt  */

	}

	svg.collection text.subblock,

	svg.collection-fixed text.subblock  {

		font-size: 4.233px;  /*  12pt  */

	}

	svg.subblock text.subblock,

	svg.subblock-fixed text.subblock  {

		font-size: 7.055px;  /*  20pt  */

	}

<!-- collection font sizes -->

	text.collection {

		font-size: 2.469px;  /*  7pt  */

	}

	svg.collection text.collection,

	svg.collection-fixed text.collection  {

		font-size: 3.7035px;  /*  10.5pt  */

	} 

<!-- borders -->

	/* thin border */

	rect.legend, rect.collection, rect.cbox {

		stroke-width: 0.0882px;  /*  0.25pt  */

		stroke: black

	}

	/* thick border */

	rect.layer, rect.subblock, rect.block  {

		stroke-width: 0.2469px;  /*  0.7pt  */

		stroke: black

	}

	rect.layer {

		fill: #e6e6e6

	}

	rect.block {

		fill: #b3b3b3

	}

	rect.subblock {

		fill: #e6e6e6

	}

	rect.collection {

		fill: white

	}

	rect.legend {

		fill: white

	}

 </style>	

 		<xsl:apply-templates select="." mode="shapes"/>

	</defs>

		<!-- next line is a hack for Xalan -->

		<xsl:comment>Drawing in static mode: <xsl:value-of select="$pre-Static=1"/></xsl:comment>	

<script type="text/ecmascript"> 

<!-- for creating / finding elements by namespace -->

var svgns="http://www.w3.org/2000/svg";

<!-- for pop-ups which can only appear one at a time. 

In general, one would want to use 

	onmouseover="on('blah') onmouseout="off('blah')"

for stuff which appears and disappears based on the position of the mouse (like dependency arrows)

for stuff which appears based on a mouseover or button press, but does not 

disappear until some other trigger (and only one can appear at a time), use one of:

	onmouseover="on(clear('blah'))"

	onclick="on(clear('blah'))"

-->

var curId = '';

function clear(id) {

	if(curId != '') off(curId);

	return curId=id;

}

<!--  for showing and hiding : 

	not used by default, but used by higher-detailed versions when Static is not set

	also used by post-processed versions for showing pop-up data.-->

function on(id) {

	var cur =document.getElementById(id)

	cur.setAttribute('visibility','visible');

	<xsl:if test="$Detail!='component'"><!-- this is needed to wrap text which is initially hidden -->

	if(!cur.hasAttribute('wrapenated')) {

		cur.setAttribute('wrapenated','true');

		wrapalltext(cur)

	}

	</xsl:if>

	return cur;

}

function off(id) {

	document.getElementById(id).setAttribute('visibility','hidden');

}

<xsl:if test="not($Static)"><!-- show level lables -->

<!--function resizeLabel(node) {

	var list = node.getElementsByTagNameNS(svgns,'text');

	if(list.length==0) return;

	var txt = list.item(0);

	node=node.firstChild;

	while(node && node.nodeType!=1) node=node.nextSibling;

	if(!node || node==txt) return;

	if(node.hasAttribute('transform')) return;

	var scale  = (1.6+txt.getComputedTextLength()) / 20;

	var x = Number(txt.getAttribute('x'))

	node.setAttribute('transform', 'translate('+ x+') scale('+scale+' 1) translate('+ (-x)+') ');

}-->

</xsl:if>

<!--  for wrapping: breaks text up into an array of words -->

function splitup(txt) {

	var a = new Array;

	var t = txt;

	var found		<!-- \u4e00-\ufa2 is the unicode range for kanjii, \u3041-\u309 is katakana and e\u30a1-\u30fe is hiragana-->

	while((found = t.match(/(^[\u3041-\u309e\u30a1-\u30fe\u4e00-\ufa2d])([\u3041-\u309e\u30a1-\u30fe\u4e00-\ufa2d].*)$/))|| ( found = t.match(/^([^ \u200b\xad-]+[ \u200b\xad-]+)(.*)$/))) {

			a.push(found[1]);

			t=found[2];

	}

	a.push(t);

	return a;

}

<!--  the remainder of the scripts also are for wrapping -->

<![CDATA[

function splitable(node) {

 	return node.firstChild.nodeType == 3 && node.firstChild.data.match(/[\t\n\r \u200b\xad-]/);

}

function crush(node, len) {

	node.setAttribute('letter-spacing','-0.1');

	if( node.getComputedTextLength() > len) 

		node.setAttribute('letter-spacing','-0.2');

}

function whatSize(txt) { // convert a length into pixels

	if(txt.match(/^[0-9.-]+$/)) return txt;

	var a = document.createElementNS(svgns,'rect');

	a.setAttribute('x',0);

	a.setAttribute('y',0);

	a.setAttribute('width',txt);

	var l = a.getBBox().width;

	delete a;

	return l;

}

function wrapalltext(node) {

    if(!node) node= document;

    var all = node.getElementsByTagNameNS(svgns,'text');

    var i=0;

    for (i=0; i<all.length; i++) {

	var cur = all.item(i);

	var w =0;

	if(cur.hasAttribute('ref')) {

		w = document.getElementById(cur.getAttribute('ref')).getBBox().width * 0.9;

	} else if (cur.hasAttribute('width')) {

		w = whatSize(cur.getAttribute('width'));

	}

	if (w)	wraptext(cur,w)

	}

}

function wraptext(cur,l) {

	if(cur.firstChild.nodeType != 3)  return; // must be just a text node

	if(cur.getBBox().width < l )  {

		cur.firstChild.data = cur.firstChild.data.replace(/[\xad\u200b]/g,"");

		return; // no need -- won't wrap

	}

	var t = cur.firstChild.data.replace(/\s+/," ");  // normalize all spaces

	t = t.replace(/^ +/,"").replace(/ +$/,"");  // trim spaces

	var words =splitup(t); 	// each word ends with the split character (if any)

	if (words.length<2)  {

		crush(cur, l);

		return;

	}

	cur.removeChild(cur.firstChild)

	var tspan = document.createElementNS(svgns,'tspan');

	cur.appendChild(tspan);

	var txt = document.createTextNode(words[0]);

	tspan.appendChild(txt);

	tspan.setAttribute('x',cur.getAttribute('x'));	// Opera needs this

	var nlines=1;

	var zero =0;

	for (i =1;i< words.length;i++) {

		var was = txt.data;

		txt.data+=words[i];

		if (tspan.getComputedTextLength() -zero > l) { // if the line with this word at the end is bigger than the available space...

			txt.data=was.replace(/ +$/,"").replace(/\xad(.)/,"$1").replace(/\u200b/g,""); // remove zero-width spaces and trailing spaces and soft hyphens

			// if it's still too big then decrease the letter spacing

			if( tspan.getComputedTextLength() > l ) 	crush(tspan,l);

			tspan = document.createElementNS(svgns,'tspan');

			tspan.setAttribute('dy',"1em");

			nlines++;

			tspan.setAttribute('x',cur.getAttribute('x'));

			cur.appendChild(tspan);

			txt = document.createTextNode('');

			tspan.appendChild(txt);

			zero = tspan.getComputedTextLength();

			txt.data+=words[i];

		}

	}

	txt.data=txt.data.replace(/ +$/,"").replace(/\xad(.)/,"$1").replace(/\u200b/g,""); // remove zero-width spaces and trailing spaces and soft hyphens

	var align =cur.getAttribute('dominant-baseline');

	if(align=='' || align=='ideographic') {

		cur.setAttribute('dy',(1-nlines)+"em");

	 } else{

	 	 if(align=='mathematical')

			cur.setAttribute('dy',((1-nlines ) / 2 )+"em");

		else if(align=='hanging') 

			cur.setAttribute('dy',"0em")

	 }

}

  ]]> </script>

<xsl:apply-templates select="systemModel/*[last()]">

	<xsl:with-param name="y" select="$groupDy"/>

</xsl:apply-templates>

	<xsl:apply-templates mode="validate"/>

</svg>

</xsl:template>

<xsl:template match="component|collection|subblock|block|layer" mode="id"><xsl:value-of select="translate(@name,' ','')"/></xsl:template>

<xsl:template name="linkable-content"><xsl:param name="show"/>

	<xsl:choose> <!-- don't use <a> unless there is a valid link -->

		<xsl:when test="string-length($Base)=0 or self::cmp">

			<xsl:copy-of select="$show"/>				

		</xsl:when>

		<xsl:otherwise>

			<a>

				<xsl:apply-templates select="." mode="link-label"/>

				<xsl:copy-of select="$show"/>

			</a>

		</xsl:otherwise>

	</xsl:choose>

</xsl:template>

<xsl:template name="display-name">

	<xsl:apply-templates select="." mode="text-filter"/>

	<xsl:if test="@font">

		<xsl:attribute name="style">font-family: '<xsl:value-of select="@font"/>'</xsl:attribute>

	</xsl:if>

	<xsl:call-template name="name-value"/>

</xsl:template>

<xsl:template name="name-value">

	<xsl:choose>

		<xsl:when test="self::cmp or self::cbox  or self::legend or self::note or self::layer[legend|note]">

			<xsl:apply-templates select="." mode="name"/>

		</xsl:when>

		<xsl:when test="@abbrev"><xsl:value-of select="@abbrev"/></xsl:when>

		<xsl:when test="self::component[name]"><xsl:value-of select="name"/></xsl:when>		<!-- deprecated abbrev forms for components -->

		<xsl:when test="@label"><xsl:value-of select="@label"/></xsl:when> <!-- for legends -->

		<xsl:when test="@lookup"><xsl:value-of select="@lookup"/></xsl:when> <!-- for legends -->

		<xsl:when test="$Use-as-name!='name' and @*[name()=$Use-as-name]"><xsl:value-of select="@*[name()=$Use-as-name]"/></xsl:when>

		<xsl:otherwise><xsl:value-of select="@name"/></xsl:otherwise>

	</xsl:choose>

</xsl:template>

<!-- ============ Detail options============ -->

<!-- don't show when not enough detail -->

<xsl:template match="component[$Detail!='component' and ($Static or /SystemDefinition/systemModel/@detail-type='fixed')]" priority="9"/>

<xsl:template match="collection[$Detail!='component' and $Detail!='collection' and ($Static  or /SystemDefinition/systemModel/@detail-type='fixed')]" priority="9"/>