|
1 ##################################################################### |
|
2 # Qt documentation build |
|
3 ##################################################################### |
|
4 |
|
5 DOCS_GENERATION_DEFINES = |
|
6 GENERATOR = $$QT_BUILD_TREE/bin/qhelpgenerator |
|
7 |
|
8 win32:!win32-g++ { |
|
9 unixstyle = false |
|
10 } else :win32-g++:isEmpty(QMAKE_SH) { |
|
11 unixstyle = false |
|
12 } else { |
|
13 unixstyle = true |
|
14 } |
|
15 |
|
16 $$unixstyle { |
|
17 QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && QT_BUILD_TREE=$$QT_BUILD_TREE QT_SOURCE_TREE=$$QT_SOURCE_TREE $$QT_BUILD_TREE/bin/qdoc3 $$DOCS_GENERATION_DEFINES |
|
18 } else { |
|
19 QDOC = cd $$QT_SOURCE_TREE/tools/qdoc3/test && set QT_BUILD_TREE=$$QT_BUILD_TREE&& set QT_SOURCE_TREE=$$QT_SOURCE_TREE&& $$QT_BUILD_TREE/bin/qdoc3.exe $$DOCS_GENERATION_DEFINES |
|
20 QDOC = $$replace(QDOC, "/", "\\") |
|
21 } |
|
22 ADP_DOCS_QDOCCONF_FILE = qt-build-docs.qdocconf |
|
23 QT_DOCUMENTATION = ($$QDOC qt-api-only.qdocconf assistant.qdocconf designer.qdocconf \ |
|
24 linguist.qdocconf qmake.qdocconf) && \ |
|
25 (cd $$QT_BUILD_TREE && \ |
|
26 $$GENERATOR doc-build/html-qt/qt.qhp -o doc/qch/qt.qch && \ |
|
27 $$GENERATOR doc-build/html-assistant/assistant.qhp -o doc/qch/assistant.qch && \ |
|
28 $$GENERATOR doc-build/html-designer/designer.qhp -o doc/qch/designer.qch && \ |
|
29 $$GENERATOR doc-build/html-linguist/linguist.qhp -o doc/qch/linguist.qch && \ |
|
30 $$GENERATOR doc-build/html-qmake/qmake.qhp -o doc/qch/qmake.qch \ |
|
31 ) |
|
32 |
|
33 win32-g++:isEmpty(QMAKE_SH) { |
|
34 QT_DOCUMENTATION = $$replace(QT_DOCUMENTATION, "/", "\\\\") |
|
35 } |
|
36 |
|
37 |
|
38 !wince*:!cross_compile:SUBDIRS += tools/qdoc3 |
|
39 |
|
40 # Build rules: |
|
41 adp_docs.commands = ($$QDOC $$ADP_DOCS_QDOCCONF_FILE) |
|
42 adp_docs.depends += sub-tools-qdoc3 |
|
43 qch_docs.commands = $$QT_DOCUMENTATION |
|
44 qch_docs.depends += sub-tools |
|
45 |
|
46 docs.depends = adp_docs qch_docs |
|
47 |
|
48 # Install rules |
|
49 htmldocs.files = $$QT_BUILD_TREE/doc/html |
|
50 htmldocs.path = $$[QT_INSTALL_DOCS] |
|
51 htmldocs.CONFIG += no_check_exist |
|
52 |
|
53 qchdocs.files= $$QT_BUILD_TREE/doc/qch |
|
54 qchdocs.path = $$[QT_INSTALL_DOCS] |
|
55 qchdocs.CONFIG += no_check_exist |
|
56 |
|
57 docimages.files = $$QT_BUILD_TREE/doc/src/images |
|
58 docimages.path = $$[QT_INSTALL_DOCS]/src |
|
59 |
|
60 QMAKE_EXTRA_TARGETS += qdoc adp_docs qch_docs docs |
|
61 INSTALLS += htmldocs qchdocs docimages |