1 # Use subdirs template to suppress generation of unnecessary files

     2 TEMPLATE = subdirs

     3 

     4 symbian: {

     5     load(data_caging_paths)

     6 

     7     SUBDIRS=

     8     # WARNING: Changing TARGET name will break Symbian SISX upgrade functionality

     9     # DO NOT TOUCH TARGET VARIABLE IF YOU ARE NOT SURE WHAT YOU ARE DOING

    10     TARGET = "Qt"

    11     TARGET.UID3 = 0x2001E61C

    12     VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}

    13 

    14     qtresources.sources = $${EPOCROOT}$$HW_ZDIR$$APP_RESOURCE_DIR/s60main.rsc

    15     qtresources.path = $$APP_RESOURCE_DIR

    16 

    17     qtlibraries.sources = \

    18         QtCore.dll \

    19         QtXml.dll \

    20         QtGui.dll \

    21         QtNetwork.dll \

    22         QtTest.dll \

    23         QtSql.dll

    24 

    25     qts60plugindeployment = \

    26         "IF package(0x1028315F)" \

    27         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_5_0.dll\" - \"!:\\sys\\bin\\qts60plugin_5_0.dll\"" \

    28         "ELSEIF package(0x102752AE)" \

    29         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_3_2.dll\" - \"!:\\sys\\bin\\qts60plugin_3_2.dll\"" \

    30         "ELSEIF package(0x102032BE)" \

    31         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_3_1.dll\" - \"!:\\sys\\bin\\qts60plugin_3_1.dll\"" \

    32         "ELSE" \

    33         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_5_0.dll\" - \"!:\\sys\\bin\\qts60plugin_5_0.dll\"" \

    34         "ENDIF"

    35     qtlibraries.pkg_postrules += qts60plugindeployment

    36 

    37     sqlitedeployment = \

    38         "; EXISTS statement does not resolve !. Lets check the most common drives" \

    39         "IF NOT EXISTS(\"c:\\sys\\bin\\sqlite3.dll\") AND NOT EXISTS(\"e:\\sys\\bin\\sqlite3.dll\") AND NOT EXISTS(\"z:\\sys\\bin\\sqlite3.dll\")" \

    40         "\"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/sqlite3.dll\" - \"!:\\sys\\bin\\sqlite3.dll\"" \

    41         "ENDIF"

    42     qtlibraries.pkg_postrules += sqlitedeployment

    43 

    44     qtlibraries.path = /sys/bin

    45 

    46     vendorinfo = \

    47         "; Localised Vendor name" \

    48         "%{\"Nokia, Qt\"}" \

    49         " " \

    50         "; Unique Vendor name" \

    51         ":\"Nokia, Qt\"" \

    52         " "

    53 

    54 

    55     qtlibraries.pkg_prerules = vendorinfo

    56     qtlibraries.pkg_prerules += "; Dependencies of Qt libraries"

    57     

    58     # Comment the following dependencies out because it is not needed in MCL

    59     

    60     #qtlibraries.pkg_prerules += "(0x20013851), 1, 5, 1, {\"PIPS Installer\"}"

    61     #contains(QT_CONFIG, openssl) | contains(QT_CONFIG, openssl-linked) {

    62     #    qtlibraries.pkg_prerules += "(0x200110CB), 1, 5, 1, {\"Open C LIBSSL Common\"}"

    63     #}

    64     #contains(CONFIG, stl) {

    65     #    qtlibraries.pkg_prerules += "(0x2000F866), 1, 0, 0, {\"Standard C++ Library Common\"}"

    66     #}

    67 

    68     !contains(QT_CONFIG, no-jpeg): imageformats_plugins.sources += qjpeg.dll

    69     !contains(QT_CONFIG, no-gif):  imageformats_plugins.sources += qgif.dll

    70     !contains(QT_CONFIG, no-mng):  imageformats_plugins.sources += qmng.dll

    71     !contains(QT_CONFIG, no-tiff): imageformats_plugins.sources += qtiff.dll

    72     !contains(QT_CONFIG, no-ico):  imageformats_plugins.sources += qico.dll

    73     imageformats_plugins.path = $$QT_PLUGINS_BASE_DIR/imageformats

    74 

    75     codecs_plugins.sources = qcncodecs.dll qjpcodecs.dll qtwcodecs.dll qkrcodecs.dll

    76     codecs_plugins.path = $$QT_PLUGINS_BASE_DIR/codecs

    77 

    78     contains(QT_CONFIG, phonon-backend) {

    79         phonon_backend_plugins.sources += phonon_mmf.dll

    80 

    81         phonon_backend_plugins.path = $$QT_PLUGINS_BASE_DIR/phonon_backend

    82         DEPLOYMENT += phonon_backend_plugins

    83     }

    84 

    85     DEPLOYMENT += qtresources qtlibraries imageformats_plugins codecs_plugins graphicssystems_plugins

    86 

    87     contains(QT_CONFIG, svg): {

    88        qtlibraries.sources += QtSvg.dll

    89        imageformats_plugins.sources += qsvg.dll

    90        iconengines_plugins.sources = qsvgicon.dll

    91        iconengines_plugins.path = $$QT_PLUGINS_BASE_DIR/iconengines

    92        DEPLOYMENT += iconengines_plugins

    93     }

    94 

    95     contains(QT_CONFIG, phonon): {

    96        qtlibraries.sources += Phonon.dll

    97     }

    98 

    99     contains(QT_CONFIG, script): {

   100         qtlibraries.sources += QtScript.dll

   101     }

   102 

   103     contains(QT_CONFIG, webkit): {

   104         qtlibraries.sources += QtWebKit.dll

   105     }

   106 

   107     graphicssystems_plugins.path = $$QT_PLUGINS_BASE_DIR/graphicssystems

   108     contains(QT_CONFIG, openvg) {

   109         qtlibraries.sources += QtOpenVG.dll

   110         graphicssystems_plugins.sources += qvggraphicssystem.dll

   111     }

   112 

   113     #BLD_INF_RULES.prj_exports += "qt.iby $$CORE_MW_LAYER_IBY_EXPORT_PATH(qt.iby)"

   114     #:QTP:QTPROD-220: Qt Examples should be exported to tools-layer

   115     #BLD_INF_RULES.prj_exports += "qtdemoapps.iby $$CORE_ADAPT_LAYER_IBY_EXPORT_PATH(core/tools/qtdemoapps.iby)"

   116 }