1 include($$QT_SOURCE_TREE/tools/shared/fontpanel/fontpanel.pri)

     2 

     3 TEMPLATE = app

     4 LANGUAGE = C++

     5 TARGET = assistant_adp

     6 

     7 CONFIG += qt warn_on

     8 

     9 unix:contains(QT_CONFIG, dbus):QT += dbus

    10 

    11 build_all:!build_pass {

    12     CONFIG -= build_all

    13     CONFIG += release

    14 }

    15 QT += xml network

    16 

    17 PROJECTNAME = Assistant

    18 DESTDIR = ../../../bin

    19 

    20 FORMS += helpdialog.ui \

    21         mainwindow.ui \

    22         tabbedbrowser.ui \

    23         topicchooser.ui

    24 

    25 SOURCES += main.cpp \

    26         helpwindow.cpp \

    27         topicchooser.cpp \

    28         docuparser.cpp \

    29         index.cpp \

    30         profile.cpp \

    31         config.cpp \

    32         helpdialog.cpp \

    33         mainwindow.cpp \

    34         tabbedbrowser.cpp \

    35         fontsettingsdialog.cpp

    36 

    37 HEADERS += helpwindow.h \

    38         topicchooser.h \

    39         docuparser.h \

    40         index.h \

    41         profile.h \

    42         helpdialog.h \

    43         mainwindow.h \

    44         tabbedbrowser.h \

    45         config.h \

    46         fontsettingsdialog.h

    47 

    48 RESOURCES += assistant.qrc

    49 

    50 contains(QT_PRODUCT, OpenSource.*):DEFINES *= QT_OPENSOURCE

    51 DEFINES += QT_KEYWORDS

    52 #DEFINES +=  QT_PALMTOPCENTER_DOCS

    53 

    54 win32 {

    55     LIBS += -lshell32

    56     RC_FILE = assistant.rc

    57 }

    58 

    59 mac {

    60     ICON = assistant.icns

    61     TARGET = Assistant_adp

    62 #    QMAKE_INFO_PLIST = Info_mac.plist

    63 }

    64 

    65 target.path=$$[QT_INSTALL_BINS]

    66 INSTALLS += target

    67 

    68 TRANSLATIONS = assistant_de.ts

    69 

    70 unix:!contains(QT_CONFIG, zlib):LIBS += -lz

    71 

    72 contains(CONFIG, static): {

    73     win32 {

    74         exists($$[QT_INSTALL_PLUGINS]/imageformats/qjpeg.lib) {

    75             QTPLUGIN += qjpeg

    76             DEFINES += USE_STATIC_JPEG_PLUGIN            

    77         }

    78     } else {

    79         exists($$[QT_INSTALL_PLUGINS]/imageformats/qjpeg.a) {

    80             QTPLUGIN += qjpeg

    81             DEFINES += USE_STATIC_JPEG_PLUGIN            

    82         }        

    83     }

    84 }