--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/mkspecs/features/symbian/qt.prf	Mon Jan 11 14:00:40 2010 +0000
@@ -0,0 +1,54 @@
+contains(DEFINES, QT_MAKEDLL)|contains(DEFINES, QT_DLL) {
+    CONFIG *= epocallowdlldata
+}
+
+CONFIG += qtmain stl
+
+load(qt)
+
+# Allow .pro files to specify include path(s) to be prepended to the list.
+#
+# This allows the project to override the default ordering, whereby paths
+# relative to $$QMAKE_INCDIR_QT always come first.  This ordering can cause
+# problems when both the epoc32/include tree and a Qt include directory
+# contain a header of the same name - in this case, the Qt header is always
+# included by virtue of its path appearing first in the SYSTEMINCLUDE
+# directives in the generated MMP file.
+#
+# To work around this situation, the following line can be added to the .pro
+# file:
+#	PREPEND_INCLUDEPATH = /epoc32/include
+#
+INCLUDEPATH = $$PREPEND_INCLUDEPATH $$INCLUDEPATH
+
+# Add dependency to Qt package to all other projects besides Qt libs.
+# Note: Qt libs with full capabilities has UID3 of 0x2001E61C,
+#       while self-signed version typically has temporary UID3 of 0xE001E61C.
+contains(CONFIG, qt):!contains(TARGET.UID3, 0x2001E61C):!contains(TARGET.UID3, 0xE001E61C) {
+    default_deployment.pkg_prerules += \
+        "; Default dependency to Qt libraries" \
+        "(0x2001E61C), $${QT_MAJOR_VERSION}, $${QT_MINOR_VERSION}, $${QT_PATCH_VERSION},  {\"Qt\"}"
+}
+
+isEmpty(TARGET.EPOCSTACKSIZE):TARGET.EPOCSTACKSIZE = 0x14000
+isEmpty(TARGET.EPOCHEAPSIZE):TARGET.EPOCHEAPSIZE = 0x020000 0x800000
+
+INCLUDEPATH += $$MW_LAYER_SYSTEMINCLUDE
+for(QTLIB, $$list($$lower($$unique(QT)))) {
+    unset(qlib)
+    isEqual(QTLIB, phonon):qlib = phonon
+    else:qlib = qt$$QTLIB
+    INCLUDEPATH += $$MW_LAYER_PUBLIC_EXPORT_PATH($$qlib)
+}
+
+contains(CONFIG, hb): {
+    INCLUDEPATH += \
+        $$MW_LAYER_PUBLIC_EXPORT_PATH(hb/hbcnf) \
+        $$MW_LAYER_PUBLIC_EXPORT_PATH(hb/hbcore) \
+        $$MW_LAYER_PUBLIC_EXPORT_PATH(hb/hbinput) \
+        $$MW_LAYER_PUBLIC_EXPORT_PATH(hb/hbservices) \
+        $$MW_LAYER_PUBLIC_EXPORT_PATH(hb/hbwidgets)
+}
+
+#add log of the warning message directly to the file instead of RDebug
+DEFINES += QT_WARNING_FILE_OUTPUT
\ No newline at end of file