--- /dev/null Thu Jan 01 00:00:00 1970 +0000
+++ b/src/qbase.pri Mon Jan 11 14:00:40 2010 +0000
@@ -0,0 +1,175 @@
+isEmpty(TARGET):error(You must set TARGET before include()'ing $${_FILE_})
+INCLUDEPATH *= $$QMAKE_INCDIR_QT/$$TARGET #just for today to have some compat
+!isEmpty(RCC_DIR): INCLUDEPATH += $$RCC_DIR
+isEmpty(QT_ARCH):!isEmpty(ARCH):QT_ARCH=$$ARCH #another compat that will rot for change #215700
+TEMPLATE = lib
+isEmpty(QT_MAJOR_VERSION) {
+ VERSION=4.6.0
+} else {
+ VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
+}
+mac:!contains(QMAKE_EXT_C, .mm):QMAKE_EXT_C += .mm
+
+#load up the headers info
+CONFIG += qt_install_headers
+HEADERS_PRI = $$QT_BUILD_TREE/include/$$TARGET/headers.pri
+include($$HEADERS_PRI, "", true)|clear(HEADERS_PRI)
+
+#version overriding
+win32 {
+ #because libnetwork.pro could be qmake'd (qmade?) before libqcore.pro we
+ #need to override the version of libq* in all other libq*'s just to be
+ #sure the same version is used
+ VERSIONS_LIST = $$split(VERSION, ".")
+ QT_LIBS_OVERRIDE = $$member(VERSIONS_LIST, 0)
+ for(lib, $$list(qtcore qtgui qtnetwork qtxml qtopengl qtsql qt3support)) {
+ eval(QMAKE_$${upper($$lib)}_VERSION_OVERRIDE = $$QT_LIBS_OVERRIDE)
+ eval(QMAKE_$${upper($$lib)}D_VERSION_OVERRIDE = $$QT_LIBS_OVERRIDE)
+ }
+}
+
+#other
+DESTDIR = $$QMAKE_LIBDIR_QT
+win32:!wince*:DLLDESTDIR = $$[QT_INSTALL_PREFIX]/bin
+
+CONFIG += qt warn_on depend_includepath
+CONFIG += qmake_cache target_qt
+CONFIG -= fix_output_dirs
+win32|mac:!macx-xcode:CONFIG += debug_and_release
+linux-g++*:QMAKE_LFLAGS += $$QMAKE_LFLAGS_NOUNDEF
+
+contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
+unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
+contains(QT_CONFIG, largefile):CONFIG += largefile
+
+#mac frameworks
+mac:!static:contains(QT_CONFIG, qt_framework) {
+ #QMAKE_FRAMEWORK_VERSION = 4.0
+ CONFIG += lib_bundle qt_no_framework_direct_includes qt_framework
+ CONFIG(debug, debug|release) {
+ !build_pass:CONFIG += build_all
+ } else { #release
+ !debug_and_release|build_pass {
+ CONFIG -= qt_install_headers #no need to install these as well
+ FRAMEWORK_HEADERS.version = Versions
+ FRAMEWORK_HEADERS.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
+ FRAMEWORK_HEADERS.path = Headers
+ equals(TARGET, QtCore) {
+ #headers generated by configure
+ !contains(FRAMEWORK_HEADERS.files, .*/qconfig.h) {
+ FRAMEWORK_HEADERS.files *= $$QT_BUILD_TREE/src/corelib/global/qconfig.h
+ }
+ }
+ }
+ QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS
+ }
+}
+
+mac {
+ CONFIG += explicitlib
+ macx-g++ {
+ QMAKE_CFLAGS += -fconstant-cfstrings
+ QMAKE_CXXFLAGS += -fconstant-cfstrings
+ }
+}
+
+win32:!shared:CONFIG += static
+
+win32-borland {
+ mng:QMAKE_CFLAGS_WARN_ON += -w-par
+ mng:QMAKE_CXXFLAGS_WARN_ON += -w-par
+ # Keep the size of the .tds file for the Qt library smaller than
+ # 34 Mbytes to avoid linking problems
+ QMAKE_CFLAGS_DEBUG += -vi -y-
+ QMAKE_CXXFLAGS_DEBUG += -vi -y-
+}
+
+win32 {
+ CONFIG += zlib
+ INCLUDEPATH += tmp
+ !static: DEFINES+=QT_MAKEDLL
+}
+symbian {
+ CONFIG += headerexport
+ shared {
+ DEFINES+=QT_MAKEDLL
+ TARGET.CAPABILITY = All -Tcb
+
+ defBlock = \
+ "$${LITERAL_HASH}ifdef WINSCW" \
+ "DEFFILE ../s60installs/bwins/$${TARGET}.def" \
+ "$${LITERAL_HASH}elif defined EABI" \
+ "DEFFILE ../s60installs/eabi/$${TARGET}.def" \
+ "$${LITERAL_HASH}endif"
+
+ #with defBlock enabled, removed exported symbols are treated as errors
+ #and there is binary compatibility between successive builds.
+ #with defBlock disabled, binary compatibility is broken every time you build
+ MMP_RULES += defBlock
+
+ #with EXPORTUNFROZEN enabled, new exports are included in the dll without
+ #needing to run abld freeze, however binary compatibility is only maintained
+ #for symbols that are frozen (and only if defBlock is also enabled)
+ #the downside of EXPORTUNFROZEN is that the linker gets run twice
+ #MMP_RULES += EXPORTUNFROZEN
+ }
+ load(armcc_warnings)
+}
+win32-borland:INCLUDEPATH += kernel
+
+aix-g++* {
+ QMAKE_CFLAGS += -mminimal-toc
+ QMAKE_CXXFLAGS += -mminimal-toc
+}
+
+embedded {
+ EMBEDDED_H = $$EMBEDDED_CPP
+}
+
+DEPENDPATH += ;$$NETWORK_H;$$KERNEL_H;$$WIDGETS_H;$$SQL_H;$$TABLE_H;$$DIALOGS_H;
+DEPENDPATH += $$ICONVIEW_H;$$OPENGL_H;$$THREAD_H;$$TOOLS_H;$$CODECS_H;
+DEPENDPATH += $$WORKSPACE_H;$$XML_H;$$STYLES_H;$$COMPAT_H
+embedded:DEPENDPATH += ;$$EMBEDDED_H
+
+!static:PRL_EXPORT_DEFINES += QT_SHARED
+
+#install directives
+include(qt_install.pri)
+
+unix:!symbian {
+ CONFIG += create_libtool create_pc explicitlib
+ QMAKE_LIBTOOL_LIBDIR = $$[QT_INSTALL_LIBS]
+ QMAKE_PRL_LIBDIR = $$[QT_INSTALL_LIBS]
+ QMAKE_PKGCONFIG_LIBDIR = $$[QT_INSTALL_LIBS]
+ QMAKE_PKGCONFIG_INCDIR = $$[QT_INSTALL_HEADERS]/$$TARGET
+ QMAKE_PKGCONFIG_CFLAGS = -I$$[QT_INSTALL_HEADERS]
+ QMAKE_PKGCONFIG_DESTDIR = pkgconfig
+ include_replace.match = $$QMAKE_INCDIR_QT
+ include_replace.replace = $$[QT_INSTALL_HEADERS]
+ lib_replace.match = $$QMAKE_LIBDIR_QT
+ lib_replace.replace = $$[QT_INSTALL_LIBS]
+ prefix_replace.match = $$QT_BUILD_TREE
+ prefix_replace.replace = $$[QT_INSTALL_PREFIX]
+ QMAKE_PRL_INSTALL_REPLACE += include_replace lib_replace
+ QMAKE_LIBTOOL_INSTALL_REPLACE += include_replace lib_replace
+ QMAKE_PKGCONFIG_INSTALL_REPLACE += include_replace lib_replace prefix_replace
+}
+
+contains(QT_PRODUCT, OpenSource.*):DEFINES *= QT_OPENSOURCE
+DEFINES *= QT_NO_CAST_TO_ASCII QT_ASCII_CAST_WARNINGS
+contains(QT_CONFIG, qt3support):DEFINES *= QT3_SUPPORT
+DEFINES *= QT_MOC_COMPAT #we don't need warnings from calling moc code in our generated code
+
+TARGET = $$qtLibraryTarget($$TARGET$$QT_LIBINFIX) #do this towards the end
+
+moc_dir.name = moc_location
+moc_dir.variable = QMAKE_MOC
+
+uic_dir.name = uic_location
+uic_dir.variable = QMAKE_UIC
+
+QMAKE_PKGCONFIG_VARIABLES += moc_dir uic_dir
+
+include(qt_targets.pri)
+
+win32:DEFINES+=_USE_MATH_DEFINES