mkspecs/features/win32/qaxcontainer.prf
author Eckhart Koeppen <eckhart.koppen@nokia.com>
Wed, 21 Apr 2010 20:15:53 +0300
branchRCL_3
changeset 13 c0432d11811c
parent 0 1918ee327afb
permissions -rw-r--r--
eb175c3290cd7ea85da4a590db9461504a4904bc

!debug_and_release|build_pass {
   CONFIG(debug, debug|release) {
      LIBS += -lQAxContainerd
   } else { 
      LIBS += -lQAxContainer
   }
} else {
   LIBS += -lQAxContainer
}

isEmpty(QMAKE_DUMPCPP) {
    win32:QMAKE_DUMPCPP = $$[QT_INSTALL_BINS]\dumpcpp.exe
}

dumpcpp_decl.commands = $$QMAKE_DUMPCPP ${QMAKE_FILE_IN} -o ${QMAKE_FILE_BASE}
qaxcontainer_compat: dumpcpp_decl.commands += -compat
dumpcpp_decl.output = ${QMAKE_FILE_BASE}.h
dumpcpp_decl.input = TYPELIBS
dumpcpp_decl.variable_out = HEADERS
dumpcpp_decl.name = DUMP
dumpcpp_decl.CONFIG += no_link
dumpcpp_decl.depends = $$QMAKE_DUMPCPP

QMAKE_EXTRA_COMPILERS += dumpcpp_decl


dumpcpp_impl.commands = $$QMAKE_DUMPCPP -donothing
dumpcpp_impl.output = ${QMAKE_FILE_BASE}.cpp
dumpcpp_impl.input = TYPELIBS
dumpcpp_impl.variable_out = SOURCES
dumpcpp_impl.name = CPP
dumpcpp_impl.depends = $$QMAKE_DUMPCPP ${QMAKE_FILE_BASE}.h

QMAKE_EXTRA_COMPILERS += dumpcpp_impl