tests/auto/qsharedmemory/test/test.pro
author Dremov Kirill (Nokia-D-MSW/Tampere) <kirill.dremov@nokia.com>
Fri, 12 Mar 2010 15:46:37 +0200
branchRCL_3
changeset 5 d3bac044e0f0
parent 0 1918ee327afb
permissions -rw-r--r--
Revision: 201007 Kit: 201008

load(qttest_p4)

include(../src/src.pri)
QT -= gui

DEFINES	+= QSHAREDMEMORY_DEBUG
DEFINES	+= QSYSTEMSEMAPHORE_DEBUG

SOURCES += ../tst_qsharedmemory.cpp
TARGET = ../tst_qsharedmemory

!wince*:win32 {
  CONFIG(debug, debug|release) {
    TARGET = ../../debug/tst_qsharedmemory
} else {
    TARGET = ../../release/tst_qsharedmemory
  }
}

wince*:{
requires(contains(QT_CONFIG,script))
QT += gui script
addFiles.sources = ../lackey/lackey.exe ../lackey/scripts
addFiles.path = lackey
DEPLOYMENT += addFiles
DEFINES += SRCDIR=\\\"\\\"
}else:symbian*{
requires(contains(QT_CONFIG,script))
QT += gui script
addFiles.sources = ../lackey/scripts
addFiles.path = /data/qsharedmemorytemp/lackey
addBin.sources = lackey.exe
addBin.path = /sys/bin
DEPLOYMENT += addFiles addBin
} else {
DEFINES += SRCDIR=\\\"$$PWD/../\\\"
}