|
1 # Qt bearer management library |
|
2 TEMPLATE = lib |
|
3 TARGET = QtBearer |
|
4 |
|
5 QT += network |
|
6 include (../../common.pri) |
|
7 |
|
8 DEFINES += QT_BUILD_BEARER_LIB QT_MAKEDLL |
|
9 |
|
10 #DEFINES += BEARER_MANAGEMENT_DEBUG |
|
11 |
|
12 PUBLIC_HEADERS += qnetworkconfiguration.h \ |
|
13 qnetworksession.h \ |
|
14 qnetworkconfigmanager.h |
|
15 |
|
16 HEADERS += $$PUBLIC_HEADERS |
|
17 SOURCES += qnetworksession.cpp \ |
|
18 qnetworkconfigmanager.cpp \ |
|
19 qnetworkconfiguration.cpp |
|
20 |
|
21 symbian: { |
|
22 contains (occ_enabled, yes) { |
|
23 message("Building with OCC enabled") |
|
24 DEFINES += OCC_FUNCTIONALITY_AVAILABLE=1 |
|
25 LIBS += -lextendedconnpref |
|
26 } else { |
|
27 message("Building without OCC support") |
|
28 } |
|
29 contains(snap_enabled, yes) { |
|
30 message("Building with SNAP support") |
|
31 DEFINES += SNAP_FUNCTIONALITY_AVAILABLE=1 |
|
32 LIBS += -lcmmanager |
|
33 } else { |
|
34 message("Building without SNAP support") |
|
35 LIBS += -lapengine |
|
36 } |
|
37 |
|
38 INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE |
|
39 |
|
40 HEADERS += qnetworkconfigmanager_s60_p.h \ |
|
41 qnetworkconfiguration_s60_p.h \ |
|
42 qnetworksession_s60_p.h |
|
43 SOURCES += qnetworkconfigmanager_s60_p.cpp \ |
|
44 qnetworkconfiguration_s60_p.cpp \ |
|
45 qnetworksession_s60_p.cpp |
|
46 |
|
47 LIBS += -lcommdb \ |
|
48 -lapsettingshandlerui \ |
|
49 -lconnmon \ |
|
50 -lcentralrepository \ |
|
51 -lesock \ |
|
52 -linsock \ |
|
53 -lecom \ |
|
54 -lefsrv \ |
|
55 -lnetmeta |
|
56 |
|
57 TARGET.CAPABILITY = ALL -TCB |
|
58 TARGET.UID3 = 0x2002AC81 |
|
59 |
|
60 QtBearerManagement.sources = QtBearer.dll |
|
61 QtBearerManagement.path = /sys/bin |
|
62 DEPLOYMENT += QtBearerManagement |
|
63 } else { |
|
64 maemo6|maemo5 { |
|
65 CONFIG += link_pkgconfig |
|
66 QT += dbus |
|
67 |
|
68 exists(../debug) { |
|
69 message("Enabling debug messages.") |
|
70 DEFINES += BEARER_MANAGEMENT_DEBUG |
|
71 } |
|
72 |
|
73 HEADERS += qnetworksession_maemo_p.h \ |
|
74 qnetworkconfigmanager_maemo_p.h \ |
|
75 qnetworkconfiguration_maemo_p.h |
|
76 |
|
77 SOURCES += qnetworkconfigmanager_maemo.cpp \ |
|
78 qnetworksession_maemo.cpp |
|
79 |
|
80 documentation.path = $$QT_MOBILITY_PREFIX/doc |
|
81 documentation.files = doc/html |
|
82 |
|
83 PKGCONFIG += glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet |
|
84 |
|
85 CONFIG += create_pc create_prl |
|
86 QMAKE_PKGCONFIG_REQUIRES = glib-2.0 dbus-glib-1 gconf-2.0 osso-ic conninet |
|
87 pkgconfig.path = $$QT_MOBILITY_LIB/pkgconfig |
|
88 pkgconfig.files = QtBearer.pc |
|
89 |
|
90 INSTALLS += pkgconfig documentation |
|
91 |
|
92 } else { |
|
93 |
|
94 DEFINES += BEARER_ENGINE |
|
95 |
|
96 HEADERS += qnetworkconfigmanager_p.h \ |
|
97 qnetworkconfiguration_p.h \ |
|
98 qnetworksession_p.h \ |
|
99 qnetworksessionengine_p.h \ |
|
100 qgenericengine_p.h |
|
101 |
|
102 SOURCES += qnetworkconfigmanager_p.cpp \ |
|
103 qnetworksession_p.cpp \ |
|
104 qnetworksessionengine.cpp \ |
|
105 qgenericengine.cpp |
|
106 |
|
107 unix:!mac:contains(networkmanager_enabled, yes) { |
|
108 contains(QT_CONFIG,dbus) { |
|
109 DEFINES += BACKEND_NM |
|
110 QT += dbus |
|
111 |
|
112 HEADERS += qnmdbushelper_p.h \ |
|
113 qnetworkmanagerservice_p.h \ |
|
114 qnmwifiengine_unix_p.h |
|
115 |
|
116 SOURCES += qnmdbushelper.cpp \ |
|
117 qnetworkmanagerservice_p.cpp \ |
|
118 qnmwifiengine_unix.cpp |
|
119 } else { |
|
120 message("NetworkManager backend requires Qt DBus support") |
|
121 } |
|
122 } |
|
123 |
|
124 win32: { |
|
125 HEADERS += qnlaengine_win_p.h \ |
|
126 qnetworksessionengine_win_p.h |
|
127 |
|
128 !wince*:HEADERS += qnativewifiengine_win_p.h |
|
129 |
|
130 SOURCES += qnlaengine_win.cpp |
|
131 |
|
132 !wince*:SOURCES += qnativewifiengine_win.cpp |
|
133 |
|
134 !wince*:LIBS += -lWs2_32 |
|
135 wince*:LIBS += -lWs2 |
|
136 } |
|
137 } |
|
138 macx: { |
|
139 HEADERS += qcorewlanengine_mac_p.h |
|
140 SOURCES+= qcorewlanengine_mac.mm |
|
141 LIBS += -framework Foundation -framework SystemConfiguration |
|
142 |
|
143 contains(corewlan_enabled, yes) { |
|
144 isEmpty(QMAKE_MAC_SDK) { |
|
145 SDK6="yes" |
|
146 } else { |
|
147 contains(QMAKE_MAC_SDK, "/Developer/SDKs/MacOSX10.6.sdk") { |
|
148 SDK6="yes" |
|
149 } |
|
150 } |
|
151 |
|
152 !isEmpty(SDK6) { |
|
153 LIBS += -framework CoreWLAN -framework Security |
|
154 DEFINES += MAC_SDK_10_6 |
|
155 } |
|
156 } |
|
157 |
|
158 |
|
159 } |
|
160 } |
|
161 |
|
162 CONFIG += middleware |
|
163 include(../../features/deploy.pri) |