1 headers.files = $$PUBLIC_HEADERS

     2 headers.path = $$QT_MOBILITY_INCLUDE

     3 

     4 contains(TEMPLATE,.*lib) {

     5     target.path=$$QT_MOBILITY_LIB

     6     TARGET = $$qtLibraryTarget($${TARGET})

     7  

     8     symbian {

     9         middleware {  path=$$MW_LAYER_PUBLIC_EXPORT_PATH("") }

    10         app {  path=$$APP_LAYER_PUBLIC_EXPORT_PATH("") }

    11 

    12         exportPath=$$EPOCROOT"."$$dirname(path)

    13         nativePath=$$replace(exportPath, /,\)

    14         exists($$nativePath) {

    15         } else {

    16             system($$QMAKE_MKDIR $$nativePath)

    17         }

    18  

    19         for(header, headers.files) {

    20             middleware {  BLD_INF_RULES.prj_exports += "$$header $$MW_LAYER_PUBLIC_EXPORT_PATH($$basename(header))"}

    21             app {  BLD_INF_RULES.prj_exports += "$$header $$APP_LAYER_PUBLIC_EXPORT_PATH($$basename(header))"}

    22         }

    23 

    24     }

    25  

    26 } else {

    27     contains(TEMPLATE,.*app):target.path=$$QT_MOBILITY_BIN

    28 }

    29 

    30 INSTALLS+=target headers

    31 

    32 mac:contains(QT_CONFIG,qt_framework) {

    33     CONFIG += lib_bundle absolute_library_soname

    34     FRAMEWORK_HEADERS.version = Versions

    35     FRAMEWORK_HEADERS.files = $${PUBLIC_HEADERS}

    36     FRAMEWORK_HEADERS.path = Headers

    37     QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS

    38 }