1 # JavaScriptCore - Qt4 build info

     2 VPATH += $$PWD

     3 

     4 INCLUDEPATH += tmp

     5 INCLUDEPATH += $$PWD $$PWD/kjs $$PWD/bindings $$PWD/bindings/c $$PWD/wtf

     6 DEFINES -= KJS_IDENTIFIER_HIDE_GLOBALS 

     7 qt-port:INCLUDEPATH += $$PWD/bindings/qt

     8 qt-port:DEFINES += BUILDING_QT__

     9 gtk-port:DEFINES += BUILDING_GTK__

    10 

    11 win32-msvc*: INCLUDEPATH += $$PWD/os-win32

    12 

    13 include(pcre/pcre.pri)

    14 

    15 LUT_FILES += \

    16     kjs/date_object.cpp \

    17     kjs/number_object.cpp \

    18     kjs/string_object.cpp \

    19     kjs/array_object.cpp \

    20     kjs/math_object.cpp \

    21     kjs/regexp_object.cpp

    22 

    23 KEYWORDLUT_FILES += \

    24     kjs/keywords.table

    25 

    26 KJSBISON += \

    27     kjs/grammar.y

    28 

    29 gtk-port: SOURCES += wtf/TCSystemAlloc.cpp

    30 

    31 SOURCES += \

    32     wtf/Assertions.cpp \

    33     wtf/HashTable.cpp \

    34     wtf/FastMalloc.cpp \

    35     bindings/NP_jsobject.cpp \

    36     bindings/npruntime.cpp \

    37     bindings/runtime_array.cpp \

    38     bindings/runtime.cpp \

    39     bindings/runtime_method.cpp \

    40     bindings/runtime_object.cpp \

    41     bindings/runtime_root.cpp \

    42     bindings/c/c_class.cpp \

    43     bindings/c/c_instance.cpp \

    44     bindings/c/c_runtime.cpp \

    45     bindings/c/c_utility.cpp \

    46     API/JSBase.cpp \

    47     API/JSCallbackConstructor.cpp \

    48     API/JSCallbackFunction.cpp \

    49     API/JSCallbackObject.cpp \

    50     API/JSClassRef.cpp \

    51     API/JSContextRef.cpp \

    52     API/JSObjectRef.cpp \

    53     API/JSStringRef.cpp \

    54     API/JSValueRef.cpp \

    55     kjs/DateMath.cpp \

    56     kjs/JSWrapperObject.cpp \

    57     kjs/PropertyNameArray.cpp \

    58     kjs/array_object.cpp \

    59     kjs/bool_object.cpp \

    60     kjs/collector.cpp \

    61     kjs/CommonIdentifiers.cpp \

    62     kjs/Context.cpp \

    63     kjs/date_object.cpp \

    64     kjs/debugger.cpp \

    65     kjs/dtoa.cpp \

    66     kjs/error_object.cpp \

    67     kjs/ExecState.cpp \

    68     kjs/fpconst.cpp \

    69     kjs/function.cpp \

    70     kjs/function_object.cpp \

    71     kjs/identifier.cpp \

    72     kjs/internal.cpp \

    73     kjs/interpreter.cpp \

    74     kjs/JSImmediate.cpp \

    75     kjs/JSLock.cpp \

    76     kjs/lexer.cpp \

    77     kjs/list.cpp \

    78     kjs/lookup.cpp \

    79     kjs/math_object.cpp \

    80     kjs/nodes.cpp \

    81     kjs/nodes2string.cpp \

    82     kjs/number_object.cpp \

    83     kjs/object.cpp \

    84     kjs/object_object.cpp \

    85     kjs/operations.cpp \

    86     kjs/Parser.cpp \

    87     kjs/property_map.cpp \

    88     kjs/property_slot.cpp \

    89     kjs/regexp.cpp \

    90     kjs/regexp_object.cpp \

    91     kjs/scope_chain.cpp \

    92     kjs/string_object.cpp \

    93     kjs/ustring.cpp \

    94     kjs/value.cpp

    95 

    96 qt-port:SOURCES += \

    97     bindings/qt/qt_class.cpp \

    98     bindings/qt/qt_instance.cpp \

    99     bindings/qt/qt_runtime.cpp

   100 

   101 

   102 # GENERATOR 1-A: LUT creator

   103 lut.output = tmp/${QMAKE_FILE_BASE}.lut.h

   104 lut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}

   105 lut.depend = ${QMAKE_FILE_NAME}

   106 lut.input = LUT_FILES

   107 lut.CONFIG += no_link

   108 QMAKE_EXTRA_COMPILERS += lut

   109 

   110 # GENERATOR 1-B: particular LUT creator (for 1 file only)

   111 keywordlut.output = tmp/lexer.lut.h

   112 keywordlut.commands = perl $$PWD/kjs/create_hash_table ${QMAKE_FILE_NAME} -i > ${QMAKE_FILE_OUT}

   113 keywordlut.depend = ${QMAKE_FILE_NAME}

   114 keywordlut.input = KEYWORDLUT_FILES

   115 keywordlut.CONFIG += no_link

   116 QMAKE_EXTRA_COMPILERS += keywordlut

   117 

   118 # GENERATOR 2: bison grammar

   119 kjsbison.output = tmp/${QMAKE_FILE_BASE}.cpp

   120 kjsbison.commands = bison -d -p kjsyy ${QMAKE_FILE_NAME} -o ${QMAKE_FILE_BASE}.tab.c && $(MOVE) ${QMAKE_FILE_BASE}.tab.c ${QMAKE_FILE_OUT} && $(MOVE) ${QMAKE_FILE_BASE}.tab.h tmp/${QMAKE_FILE_BASE}.h

   121 kjsbison.depend = ${QMAKE_FILE_NAME}

   122 kjsbison.input = KJSBISON

   123 kjsbison.variable_out = GENERATED_SOURCES

   124 kjsbison.dependency_type = TYPE_C

   125 kjsbison.CONFIG = target_predeps

   126 kjsbison.clean = ${QMAKE_FILE_OUT} tmp/${QMAKE_FILE_BASE}.h

   127 QMAKE_EXTRA_COMPILERS += kjsbison