--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/resourcemgmt/hwresourcesmgr/server/group/HWRMServer.mmp	Tue Feb 02 00:53:00 2010 +0200
@@ -0,0 +1,95 @@
+// Copyright (c) 2006-2009 Nokia Corporation and/or its subsidiary(-ies).
+// All rights reserved.
+// This component and the accompanying materials are made available
+// under the terms of "Eclipse Public License v1.0"
+// which accompanies this distribution, and is available
+// at the URL "http://www.eclipse.org/legal/epl-v10.html".
+//
+// Initial Contributors:
+// Nokia Corporation - initial contribution.
+//
+// Contributors:
+//
+// Description:
+//
+
+
+
+
+TARGET          hwrmserver.exe
+TARGETTYPE      exe
+
+TARGETPATH	sys/bin
+
+// Since this is an exe with no alternate implementations, 
+// just use same UID for both UID2 and UID3
+UID             0x101F7A02 0x101F7A02
+VENDORID        0x70000001
+CAPABILITY	     ReadDeviceData WriteDeviceData ProtServ CommDD
+
+SOURCEPATH	     ../src
+SOURCE          HWRMServerStartup.cpp
+SOURCE          HWRMServer.cpp
+SOURCE          HWRMSession.cpp
+SOURCE          HWRMServerActiveScheduler.cpp
+SOURCE          HWRMService.cpp
+SOURCE          HWRMLightService.cpp
+SOURCE          HWRMVibraService.cpp
+SOURCE          HWRMPowerService.cpp
+SOURCE          HWRMFmTxService.cpp
+SOURCE          HWRMGenericTimer.cpp
+SOURCE          HWRMVibraCommonData.cpp
+SOURCE          HWRMLightCommonData.cpp
+SOURCE          HWRMPowerCommonData.cpp
+SOURCE          HWRMFmTxCommonData.cpp
+SOURCE			HWRMFmTxRdsTextConverter.cpp
+SOURCE          HWRMFmTxStateUtility.cpp
+SOURCE          HWRMPluginHandler.cpp
+SOURCE          HWRMPluginTransactionList.cpp
+SOURCE          HWRMPolicy.cpp
+SOURCE          HWRMReservationHandler.cpp
+SOURCE          HWRMLightsTimeoutObserver.cpp
+SOURCE          HWRMPSChangeObserver.cpp
+SOURCE          HWRMPowerStatePluginHandler.cpp
+SOURCE          HWRMFmTxPowersaveTimer.cpp
+SOURCE          HWRMVibraCommonService.cpp
+SOURCE          HWRMFeatureMgr.cpp
+
+SOURCEPATH      ../../common/src
+SOURCE			cenrepobserver.cpp
+
+USERINCLUDE     ../inc
+USERINCLUDE     ../plugininc
+USERINCLUDE     ../../include
+USERINCLUDE     ../../common/inc
+USERINCLUDE     ../../client/inc
+USERINCLUDE     ../../light/inc
+USERINCLUDE     ../../vibra/inc
+USERINCLUDE     ../../power/inc
+USERINCLUDE     ../../../../resourceinterfaces/fmtransmittercontrol/inc
+
+OS_LAYER_SYSTEMINCLUDE_SYMBIAN
+
+//DEBUGLIBRARY	comsdbgutil.lib
+LIBRARY         efsrv.lib
+LIBRARY         estor.lib
+LIBRARY         euser.lib
+LIBRARY         centralrepository.lib
+LIBRARY         ecom.lib
+LIBRARY         hwrmcommon.lib
+LIBRARY         featmgr.lib
+
+LANG			SC
+
+#include <comms-infras/commsdebugutility.mmh>
+#include "HWRMServer.mmh"
+
+// logging
+macro HWRM_SERVER
+//macro DISABLE_COMPONENT_TRACE //enable this macro to switch of debug logging
+
+// Enable this macro to enable audio routing flag
+// control from test code. 
+MACRO INSECURE_AUDIO_POLICY_KEYS
+
+SMPSAFE