# WebCore - qmake build info

CONFIG += building-libs

CONFIG += depend_includepath

symbian: {

    TARGET.EPOCALLOWDLLDATA=1

    TARGET.EPOCHEAPSIZE = 0x20000 0x2000000 // Min 128kB, Max 32MB

    TARGET.CAPABILITY = All -Tcb

    webkitlibs.path = /sys/bin

    vendorinfo = \

        "; Localised Vendor name" \

        "%{\"Nokia, Qt\"}" \

        " " \

        "; Unique Vendor name" \

        ":\"Nokia, Qt\"" \

        " "

    webkitlibs.pkg_prerules = vendorinfo

    webkitbackup.sources = ../WebKit/qt/symbian/backup_registration.xml

    webkitbackup.path = /private/10202D56/import/packages/$$replace(TARGET.UID3, 0x,)

    DEPLOYMENT += webkitlibs webkitbackup

    # RO text (code) section in qtwebkit.dll exceeds allocated space for gcce udeb target.

    # Move RW-section base address to start from 0xE00000 instead of the toolchain default 0x400000.

    MMP_RULES += ALWAYS_BUILD_AS_ARM

    QMAKE_CXXFLAGS.ARMCC += -OTime -O3

    QMAKE_LFLAGS.ARMCC += --rw-base 0xE00000

}

include($$PWD/../WebKit.pri)

TEMPLATE = lib

TARGET = QtWebKit

contains(QT_CONFIG, embedded):CONFIG += embedded

CONFIG(QTDIR_build) {

    GENERATED_SOURCES_DIR = $$PWD/generated

    include($$QT_SOURCE_TREE/src/qbase.pri)

    PRECOMPILED_HEADER = $$PWD/../WebKit/qt/WebKit_pch.h

    DEFINES *= NDEBUG

} else {

    !static: DEFINES += QT_MAKEDLL

    CONFIG(debug, debug|release) {

        isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = generated$${QMAKE_DIR_SEP}debug

        OBJECTS_DIR = obj/debug

    } else { # Release

        isEmpty(GENERATED_SOURCES_DIR):GENERATED_SOURCES_DIR = generated$${QMAKE_DIR_SEP}release

        OBJECTS_DIR = obj/release

    }

    DESTDIR = $$OUTPUT_DIR/lib

}

GENERATED_SOURCES_DIR_SLASH = $$GENERATED_SOURCES_DIR${QMAKE_DIR_SEP}

unix {

    QMAKE_PKGCONFIG_REQUIRES = QtCore QtGui QtNetwork

    lessThan(QT_MINOR_VERSION, 4): QMAKE_PKGCONFIG_REQUIRES += QtXml

}

unix:!mac:*-g++*:QMAKE_CXXFLAGS += -ffunction-sections -fdata-sections 

unix:!mac:*-g++*:QMAKE_LFLAGS += -Wl,--gc-sections

CONFIG(release):!CONFIG(QTDIR_build) {

    contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols

    unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions

}

linux-*: DEFINES += HAVE_STDINT_H

freebsd-*: DEFINES += HAVE_PTHREAD_NP_H

DEFINES += BUILD_WEBKIT

# Remove whole program optimizations due to miscompilations

win32-msvc2005|win32-msvc2008:{

    QMAKE_CFLAGS_RELEASE -= -GL

    QMAKE_CXXFLAGS_RELEASE -= -GL

}

win32-*: DEFINES += _HAS_TR1=0

wince* {

#    DEFINES += ENABLE_SVG=0 ENABLE_XPATH=0 ENABLE_XBL=0 \

#               ENABLE_SVG_ANIMATION=0 ENABLE_SVG_USE=0  \

#               ENABLE_SVG_FOREIGN_OBJECT=0 ENABLE_SVG_AS_IMAGE=0

    INCLUDEPATH += $$PWD/../JavaScriptCore/os-wince

    INCLUDEPATH += $$PWD/../JavaScriptCore/os-win32

}

# Pick up 3rdparty libraries from INCLUDE/LIB just like with MSVC

win32-g++ {

    TMPPATH            = $$quote($$(INCLUDE))

    QMAKE_INCDIR_POST += $$split(TMPPATH,";")

    TMPPATH            = $$quote($$(LIB))

    QMAKE_LIBDIR_POST += $$split(TMPPATH,";")

}

# Assume that symbian OS always comes with sqlite

symbian:!CONFIG(QTDIR_build): CONFIG += system-sqlite

# Try to locate sqlite3 source

CONFIG(QTDIR_build) {

    SQLITE3SRCDIR = $$QT_SOURCE_TREE/src/3rdparty/sqlite/

} else {

    SQLITE3SRCDIR = $$(SQLITE3SRCDIR)

    isEmpty(SQLITE3SRCDIR) {

        SQLITE3SRCDIR = $$[QT_INSTALL_PREFIX]/src/3rdparty/sqlite/

    } 

}

# Optional components (look for defs in config.h and included files!)

contains(DEFINES, ENABLE_SINGLE_THREADED=1) {

    DEFINES+=ENABLE_DATABASE=0 ENABLE_DOM_STORAGE=0 ENABLE_ICONDATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0

}

# turn off SQLITE support if we do not have sqlite3 available

!CONFIG(QTDIR_build):win32-*:!exists( $${SQLITE3SRCDIR}/sqlite3.c ): DEFINES += ENABLE_SQLITE=0 ENABLE_DATABASE=0 ENABLE_ICONDATABASE=0 ENABLE_OFFLINE_WEB_APPLICATIONS=0 ENABLE_DOM_STORAGE=0

!contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=.): DEFINES += ENABLE_JAVASCRIPT_DEBUGGER=1

!contains(DEFINES, ENABLE_DATABASE=.): DEFINES += ENABLE_DATABASE=1

!contains(DEFINES, ENABLE_EVENTSOURCE=.): DEFINES += ENABLE_EVENTSOURCE=1

!contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=.): DEFINES += ENABLE_OFFLINE_WEB_APPLICATIONS=1

!contains(DEFINES, ENABLE_DOM_STORAGE=.): DEFINES += ENABLE_DOM_STORAGE=1

!contains(DEFINES, ENABLE_ICONDATABASE=.): DEFINES += ENABLE_ICONDATABASE=1

!contains(DEFINES, ENABLE_CHANNEL_MESSAGING=.): DEFINES += ENABLE_CHANNEL_MESSAGING=1

!contains(DEFINES, ENABLE_ORIENTATION_EVENTS=.): DEFINES += ENABLE_ORIENTATION_EVENTS=0

# turn on SQLITE support if any of the dependent features are turned on

!contains(DEFINES, ENABLE_SQLITE=.) {

  contains(DEFINES, ENABLE_DATABASE=1)|contains(DEFINES, ENABLE_ICONDATABASE=1)|contains(DEFINES, ENABLE_DOM_STORAGE=1)|contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1) {

    DEFINES += ENABLE_SQLITE=1

  } else {

    DEFINES += ENABLE_SQLITE=0

  }

}

!contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=.): DEFINES += ENABLE_DASHBOARD_SUPPORT=0

!contains(DEFINES, ENABLE_FILTERS=.): DEFINES += ENABLE_FILTERS=0

!contains(DEFINES, ENABLE_XPATH=.): DEFINES += ENABLE_XPATH=1

#!contains(DEFINES, ENABLE_XBL=.): DEFINES += ENABLE_XBL=1

!contains(DEFINES, ENABLE_WCSS=.): DEFINES += ENABLE_WCSS=0

!contains(DEFINES, ENABLE_WML=.): DEFINES += ENABLE_WML=0

!contains(DEFINES, ENABLE_SHARED_WORKERS=.): DEFINES += ENABLE_SHARED_WORKERS=1

!contains(DEFINES, ENABLE_WORKERS=.): DEFINES += ENABLE_WORKERS=1

!contains(DEFINES, ENABLE_XHTMLMP=.): DEFINES += ENABLE_XHTMLMP=0

!contains(DEFINES, ENABLE_DATAGRID=.): DEFINES += ENABLE_DATAGRID=0

# SVG support

!contains(DEFINES, ENABLE_SVG=0) {

    !contains(DEFINES, ENABLE_SVG=.): DEFINES += ENABLE_SVG=1

    !contains(DEFINES, ENABLE_SVG_FONTS=.): DEFINES += ENABLE_SVG_FONTS=1

    !contains(DEFINES, ENABLE_SVG_FOREIGN_OBJECT=.): DEFINES += ENABLE_SVG_FOREIGN_OBJECT=1

    !contains(DEFINES, ENABLE_SVG_ANIMATION=.): DEFINES += ENABLE_SVG_ANIMATION=1

    !contains(DEFINES, ENABLE_SVG_AS_IMAGE=.): DEFINES += ENABLE_SVG_AS_IMAGE=1

    !contains(DEFINES, ENABLE_SVG_USE=.): DEFINES += ENABLE_SVG_USE=1

} else {

    DEFINES += ENABLE_SVG_FONTS=0 ENABLE_SVG_FOREIGN_OBJECT=0 ENABLE_SVG_ANIMATION=0 ENABLE_SVG_AS_IMAGE=0 ENABLE_SVG_USE=0

}

# HTML5 ruby support

!contains(DEFINES, ENABLE_RUBY=.): DEFINES += ENABLE_RUBY=1

# HTML5 media support

!contains(DEFINES, ENABLE_VIDEO=.) {

    contains(QT_CONFIG, phonon):DEFINES += ENABLE_VIDEO=1

    else:DEFINES += ENABLE_VIDEO=0

}

# HTML5 datalist support

!contains(DEFINES, ENABLE_DATALIST=.): DEFINES += ENABLE_DATALIST=1

# Nescape plugins support (NPAPI)

!contains(DEFINES, ENABLE_NETSCAPE_PLUGIN_API=.) {

    unix|win32-*:!embedded:!wince*: {

        DEFINES += ENABLE_NETSCAPE_PLUGIN_API=1

    } else {

        DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0

    }

}

# Web Socket support.

!contains(DEFINES, ENABLE_WEB_SOCKETS=.): DEFINES += ENABLE_WEB_SOCKETS=0

# XSLT support with QtXmlPatterns

!contains(DEFINES, ENABLE_XSLT=.) {

    contains(QT_CONFIG, xmlpatterns):!lessThan(QT_MINOR_VERSION, 5):DEFINES += ENABLE_XSLT=1

    else:DEFINES += ENABLE_XSLT=0

}

!CONFIG(QTDIR_build):!contains(DEFINES, ENABLE_QT_BEARER=.) {

    symbian: {

        exists($${EPOCROOT}epoc32/release/winscw/udeb/QtBearer.lib)| \

        exists($${EPOCROOT}epoc32/release/armv5/lib/QtBearer.lib) {

            DEFINES += ENABLE_QT_BEARER=1

        }

    }

}

DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1 WTF_CHANGES=1

# Used to compute defaults for the build-webkit script

CONFIG(compute_defaults) {

    message($$DEFINES)

    error("Done computing defaults")

}

RESOURCES += \

    $$PWD/../WebCore/WebCore.qrc

!symbian {

    RESOURCES += $$PWD/../WebCore/inspector/front-end/WebKit.qrc

}

include($$PWD/../JavaScriptCore/JavaScriptCore.pri)

INCLUDEPATH = \

    $$PWD \

    $$PWD/accessibility \

    $$PWD/bindings/js \

    $$PWD/bridge \

    $$PWD/bridge/c \

    $$PWD/css \

    $$PWD/dom \

    $$PWD/dom/default \

    $$PWD/editing \

    $$PWD/history \

    $$PWD/html \

    $$PWD/html/canvas \

    $$PWD/inspector \

    $$PWD/loader \

    $$PWD/loader/appcache \

    $$PWD/loader/archive \

    $$PWD/loader/icon \

    $$PWD/notifications \

    $$PWD/page \

    $$PWD/page/animation \

    $$PWD/platform \

    $$PWD/platform/animation \

    $$PWD/platform/graphics \

    $$PWD/platform/graphics/filters \

    $$PWD/platform/graphics/transforms \

    $$PWD/platform/image-decoders \

    $$PWD/platform/mock \

    $$PWD/platform/network \

    $$PWD/platform/sql \

    $$PWD/platform/text \

    $$PWD/plugins \

    $$PWD/rendering \

    $$PWD/rendering/style \

    $$PWD/storage \

    $$PWD/svg \

    $$PWD/svg/animation \

    $$PWD/svg/graphics \

    $$PWD/svg/graphics/filters \

    $$PWD/websockets \

    $$PWD/wml \

    $$PWD/workers \

    $$PWD/xml \

    $$GENERATED_SOURCES_DIR \

    $$INCLUDEPATH

INCLUDEPATH = \

    $$PWD/bridge/qt \

    $$PWD/page/qt \

    $$PWD/platform/graphics/qt \

    $$PWD/platform/network/qt \

    $$PWD/platform/qt \

    $$PWD/../WebKit/qt/WebCoreSupport \

    $$INCLUDEPATH

QT += network

lessThan(QT_MINOR_VERSION, 4): QT += xml

QMAKE_EXTRA_TARGETS += generated_files

FEATURE_DEFINES_JAVASCRIPT = LANGUAGE_JAVASCRIPT=1

TOKENIZER = $$PWD/css/tokenizer.flex

DOCTYPESTRINGS = $$PWD/html/DocTypeStrings.gperf

CSSBISON = $$PWD/css/CSSGrammar.y

HTML_NAMES = $$PWD/html/HTMLTagNames.in

XML_NAMES = $$PWD/xml/xmlattrs.in

ENTITIES_GPERF = $$PWD/html/HTMLEntityNames.gperf

COLORDAT_GPERF = $$PWD/platform/ColorData.gperf

WALDOCSSPROPS = $$PWD/css/CSSPropertyNames.in

WALDOCSSVALUES = $$PWD/css/CSSValueKeywords.in

DASHBOARDSUPPORTCSSPROPERTIES = $$PWD/css/DashboardSupportCSSPropertyNames.in

contains(DEFINES, ENABLE_SVG=1) {

    EXTRACSSPROPERTIES += $$PWD/css/SVGCSSPropertyNames.in

    EXTRACSSVALUES += $$PWD/css/SVGCSSValueKeywords.in

}

contains(DEFINES, ENABLE_WCSS=1) {

    EXTRACSSPROPERTIES += $$PWD/css/WCSSPropertyNames.in

    EXTRACSSVALUES += $$PWD/css/WCSSValueKeywords.in

}

STYLESHEETS_EMBED = \

    $$PWD/css/html.css \

    $$PWD/css/quirks.css \

    $$PWD/css/svg.css \

    $$PWD/css/view-source.css \

    $$PWD/css/wml.css \

    $$PWD/css/mediaControls.css \

    $$PWD/css/mediaControlsQt.css

DOMLUT_FILES += \

    bindings/js/JSDOMWindowBase.cpp \

    bindings/js/JSWorkerContextBase.cpp

IDL_BINDINGS += \

    css/Counter.idl \

    css/CSSCharsetRule.idl \

    css/CSSFontFaceRule.idl \

    css/CSSImportRule.idl \

    css/CSSMediaRule.idl \

    css/CSSPageRule.idl \

    css/CSSPrimitiveValue.idl \

    css/CSSRule.idl \

    css/CSSRuleList.idl \

    css/CSSStyleDeclaration.idl \

    css/CSSStyleRule.idl \

    css/CSSStyleSheet.idl \

    css/CSSValue.idl \

    css/CSSValueList.idl \

    css/CSSVariablesDeclaration.idl \

    css/CSSVariablesRule.idl \

    css/Media.idl \

    css/MediaList.idl \

    css/RGBColor.idl \

    css/Rect.idl \

    css/StyleSheet.idl \

    css/StyleSheetList.idl \

    css/WebKitCSSKeyframeRule.idl \

    css/WebKitCSSKeyframesRule.idl \

    css/WebKitCSSMatrix.idl \

    css/WebKitCSSTransformValue.idl \

    dom/Attr.idl \

    dom/BeforeLoadEvent.idl \

    dom/CharacterData.idl \

    dom/ClientRect.idl \

    dom/ClientRectList.idl \

    dom/Clipboard.idl \

    dom/CDATASection.idl \

    dom/Comment.idl \

    dom/DocumentFragment.idl \

    dom/Document.idl \

    dom/DocumentType.idl \

    dom/DOMCoreException.idl \

    dom/DOMImplementation.idl \

    dom/Element.idl \

    dom/Entity.idl \

    dom/EntityReference.idl \

    dom/ErrorEvent.idl \

    dom/Event.idl \

    dom/EventException.idl \

#    dom/EventListener.idl \

#    dom/EventTarget.idl \

    dom/KeyboardEvent.idl \

    dom/MouseEvent.idl \

    dom/MessageChannel.idl \

    dom/MessageEvent.idl \

    dom/MessagePort.idl \

    dom/MutationEvent.idl \

    dom/NamedNodeMap.idl \

    dom/Node.idl \

    dom/NodeFilter.idl \

    dom/NodeIterator.idl \

    dom/NodeList.idl \

    dom/Notation.idl \

    dom/OverflowEvent.idl \

    dom/PageTransitionEvent.idl \

    dom/ProcessingInstruction.idl \

    dom/ProgressEvent.idl \

    dom/RangeException.idl \

    dom/Range.idl \

    dom/Text.idl \

    dom/TextEvent.idl \

    dom/TreeWalker.idl \

    dom/UIEvent.idl \

    dom/WebKitAnimationEvent.idl \

    dom/WebKitTransitionEvent.idl \

    dom/WheelEvent.idl \

    html/canvas/CanvasArray.idl \

    html/canvas/CanvasArrayBuffer.idl \

    html/canvas/CanvasByteArray.idl \

    html/canvas/CanvasFloatArray.idl \

    html/canvas/CanvasGradient.idl \

    html/canvas/CanvasIntArray.idl \

    html/canvas/CanvasPattern.idl \

    html/canvas/CanvasRenderingContext.idl \

    html/canvas/CanvasRenderingContext2D.idl \

    html/canvas/CanvasRenderingContext3D.idl \

    html/canvas/CanvasShortArray.idl \

    html/canvas/CanvasUnsignedByteArray.idl \

    html/canvas/CanvasUnsignedIntArray.idl \

    html/canvas/CanvasUnsignedShortArray.idl \

    html/DataGridColumn.idl \

    html/DataGridColumnList.idl \

    html/File.idl \

    html/FileList.idl \

    html/HTMLAllCollection.idl \

    html/HTMLAudioElement.idl \

    html/HTMLAnchorElement.idl \

    html/HTMLAppletElement.idl \

    html/HTMLAreaElement.idl \

    html/HTMLBaseElement.idl \

    html/HTMLBaseFontElement.idl \

    html/HTMLBlockquoteElement.idl \

    html/HTMLBodyElement.idl \

    html/HTMLBRElement.idl \

    html/HTMLButtonElement.idl \

    html/HTMLCanvasElement.idl \

    html/HTMLCollection.idl \

    html/HTMLDataGridElement.idl \

    html/HTMLDataGridCellElement.idl \

    html/HTMLDataGridColElement.idl \

    html/HTMLDataGridRowElement.idl \

    html/HTMLDataListElement.idl \

    html/HTMLDirectoryElement.idl \

    html/HTMLDivElement.idl \

    html/HTMLDListElement.idl \

    html/HTMLDocument.idl \

    html/HTMLElement.idl \

    html/HTMLEmbedElement.idl \

    html/HTMLFieldSetElement.idl \

    html/HTMLFontElement.idl \

    html/HTMLFormElement.idl \

    html/HTMLFrameElement.idl \

    html/HTMLFrameSetElement.idl \

    html/HTMLHeadElement.idl \

    html/HTMLHeadingElement.idl \

    html/HTMLHRElement.idl \

    html/HTMLHtmlElement.idl \

    html/HTMLIFrameElement.idl \

    html/HTMLImageElement.idl \

    html/HTMLInputElement.idl \

    html/HTMLIsIndexElement.idl \

    html/HTMLLabelElement.idl \

    html/HTMLLegendElement.idl \

    html/HTMLLIElement.idl \

    html/HTMLLinkElement.idl \

    html/HTMLMapElement.idl \

    html/HTMLMarqueeElement.idl \

    html/HTMLMediaElement.idl \

    html/HTMLMenuElement.idl \

    html/HTMLMetaElement.idl \

    html/HTMLModElement.idl \

    html/HTMLObjectElement.idl \

    html/HTMLOListElement.idl \

    html/HTMLOptGroupElement.idl \

    html/HTMLOptionElement.idl \

    html/HTMLOptionsCollection.idl \

    html/HTMLParagraphElement.idl \

    html/HTMLParamElement.idl \

    html/HTMLPreElement.idl \

    html/HTMLQuoteElement.idl \

    html/HTMLScriptElement.idl \

    html/HTMLSelectElement.idl \

    html/HTMLSourceElement.idl \

    html/HTMLStyleElement.idl \

    html/HTMLTableCaptionElement.idl \

    html/HTMLTableCellElement.idl \

    html/HTMLTableColElement.idl \

    html/HTMLTableElement.idl \

    html/HTMLTableRowElement.idl \

    html/HTMLTableSectionElement.idl \

    html/HTMLTextAreaElement.idl \

    html/HTMLTitleElement.idl \

    html/HTMLUListElement.idl \

    html/HTMLVideoElement.idl \

    html/ImageData.idl \

    html/MediaError.idl \

    html/TextMetrics.idl \

    html/TimeRanges.idl \

    html/ValidityState.idl \

    html/VoidCallback.idl \

    inspector/InspectorBackend.idl \

    inspector/JavaScriptCallFrame.idl \

    loader/appcache/DOMApplicationCache.idl \

    page/BarInfo.idl \

    page/Console.idl \

    page/Coordinates.idl \

    page/DOMSelection.idl \

    page/DOMWindow.idl \

    page/EventSource.idl \

    page/Geolocation.idl \

    page/Geoposition.idl \

    page/History.idl \

    page/Location.idl \

    page/Navigator.idl \

    page/PositionError.idl \

    page/Screen.idl \

    page/WebKitPoint.idl \

    page/WorkerNavigator.idl \

    plugins/Plugin.idl \

    plugins/MimeType.idl \

    plugins/PluginArray.idl \

    plugins/MimeTypeArray.idl \