include(../common.pri)

CONFIG(standalone_package) {

    isEmpty(WC_GENERATED_SOURCES_DIR):WC_GENERATED_SOURCES_DIR = $$PWD/generated

} else {

    isEmpty(WC_GENERATED_SOURCES_DIR):WC_GENERATED_SOURCES_DIR = generated

}

CONFIG(minimal) {

  DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0

}

## load mobilityconfig if mobility is available 

load(mobilityconfig, true)

## Define default features macros for optional components

## (look for defs in config.h and included files!)

# Try to locate sqlite3 source

CONFIG(QTDIR_build) {

    SQLITE3SRCDIR = $$QT_SOURCE_TREE/src/3rdparty/sqlite/

} else {

    SQLITE3SRCDIR = $$(SQLITE3SRCDIR)

    isEmpty(SQLITE3SRCDIR) {

        SQLITE3SRCDIR = $$[QT_INSTALL_PREFIX]/src/3rdparty/sqlite/

    }

}

contains(DEFINES, ENABLE_SINGLE_THREADED=1) {

    DEFINES+=ENABLE_DATABASE=0 ENABLE_DOM_STORAGE=0 ENABLE_ICONDATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0

}

# turn off SQLITE support if we do not have sqlite3 available

!CONFIG(QTDIR_build):win32-*:!exists( $${SQLITE3SRCDIR}/sqlite3.c ): DEFINES += ENABLE_SQLITE=0 ENABLE_DATABASE=0 ENABLE_WORKERS=0 ENABLE_SHARED_WORKERS=0 ENABLE_ICONDATABASE=0 ENABLE_OFFLINE_WEB_APPLICATIONS=0 ENABLE_DOM_STORAGE=0

!contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=.): DEFINES += ENABLE_JAVASCRIPT_DEBUGGER=1

!contains(DEFINES, ENABLE_DATABASE=.): DEFINES += ENABLE_DATABASE=1

!contains(DEFINES, ENABLE_EVENTSOURCE=.): DEFINES += ENABLE_EVENTSOURCE=1

!contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=.): DEFINES += ENABLE_OFFLINE_WEB_APPLICATIONS=1

!contains(DEFINES, ENABLE_DOM_STORAGE=.): DEFINES += ENABLE_DOM_STORAGE=1

!contains(DEFINES, ENABLE_ICONDATABASE=.): DEFINES += ENABLE_ICONDATABASE=1

!contains(DEFINES, ENABLE_CHANNEL_MESSAGING=.): DEFINES += ENABLE_CHANNEL_MESSAGING=1

!contains(DEFINES, ENABLE_ORIENTATION_EVENTS=.): DEFINES += ENABLE_ORIENTATION_EVENTS=0

!contains(DEFINES, ENABLE_DIRECTORY_UPLOAD=.): DEFINES += ENABLE_DIRECTORY_UPLOAD=0

# turn on SQLITE support if any of the dependent features are turned on

!contains(DEFINES, ENABLE_SQLITE=.) {

  contains(DEFINES, ENABLE_DATABASE=1)|contains(DEFINES, ENABLE_ICONDATABASE=1)|contains(DEFINES, ENABLE_DOM_STORAGE=1)|contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1) {

    DEFINES += ENABLE_SQLITE=1

  } else {

    DEFINES += ENABLE_SQLITE=0

  }

}

!contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=.): DEFINES += ENABLE_DASHBOARD_SUPPORT=0

!contains(DEFINES, ENABLE_FILTERS=.): DEFINES += ENABLE_FILTERS=1

!contains(DEFINES, ENABLE_XPATH=.): DEFINES += ENABLE_XPATH=1

#!contains(DEFINES, ENABLE_XBL=.): DEFINES += ENABLE_XBL=1

!contains(DEFINES, ENABLE_WCSS=.): DEFINES += ENABLE_WCSS=0

!contains(DEFINES, ENABLE_WML=.): DEFINES += ENABLE_WML=0

!contains(DEFINES, ENABLE_SHARED_WORKERS=.): DEFINES += ENABLE_SHARED_WORKERS=1

!contains(DEFINES, ENABLE_WORKERS=.): DEFINES += ENABLE_WORKERS=1

!contains(DEFINES, ENABLE_XHTMLMP=.): DEFINES += ENABLE_XHTMLMP=0

!contains(DEFINES, ENABLE_DATAGRID=.): DEFINES += ENABLE_DATAGRID=0

!contains(DEFINES, ENABLE_RUBY=.): DEFINES += ENABLE_RUBY=1

!contains(DEFINES, ENABLE_SANDBOX=.): DEFINES += ENABLE_SANDBOX=1

!contains(DEFINES, ENABLE_METER_TAG=.): DEFINES += ENABLE_METER_TAG=1

!contains(DEFINES, ENABLE_PROGRESS_TAG=.): DEFINES += ENABLE_PROGRESS_TAG=1

!contains(DEFINES, ENABLE_BLOB_SLICE=.): DEFINES += ENABLE_BLOB_SLICE=0

!contains(DEFINES, ENABLE_NOTIFICATIONS=.): DEFINES += ENABLE_NOTIFICATIONS=1

!contains(DEFINES, ENABLE_IMAGE_RESIZER=.): DEFINES += ENABLE_IMAGE_RESIZER=0

!contains(DEFINES, ENABLE_INPUT_SPEECH=.): DEFINES += ENABLE_INPUT_SPEECH=0

!contains(DEFINES, ENABLE_HAPTICS=.): DEFINES += ENABLE_HAPTICS=1

greaterThan(QT_MINOR_VERSION, 5) {

    !contains(DEFINES, ENABLE_3D_RENDERING=.): DEFINES += ENABLE_3D_RENDERING=1

}

symbian {

#    "$${LITERAL_HASH}ifdef WINSCW"

#        DEFINES += ENABLE_SVG=0

#    "$${LITERAL_HASH}endif"

}

# SVG support

!contains(DEFINES, ENABLE_SVG=0) {

    !contains(DEFINES, ENABLE_SVG=.): DEFINES += ENABLE_SVG=1

    !contains(DEFINES, ENABLE_SVG_FONTS=.): DEFINES += ENABLE_SVG_FONTS=1

    !contains(DEFINES, ENABLE_SVG_FOREIGN_OBJECT=.): DEFINES += ENABLE_SVG_FOREIGN_OBJECT=1

    !contains(DEFINES, ENABLE_SVG_ANIMATION=.): DEFINES += ENABLE_SVG_ANIMATION=1

    !contains(DEFINES, ENABLE_SVG_AS_IMAGE=.): DEFINES += ENABLE_SVG_AS_IMAGE=1

    !contains(DEFINES, ENABLE_SVG_USE=.): DEFINES += ENABLE_SVG_USE=1

} else {

    DEFINES += ENABLE_SVG_FONTS=0 ENABLE_SVG_FOREIGN_OBJECT=0 ENABLE_SVG_ANIMATION=0 ENABLE_SVG_AS_IMAGE=0 ENABLE_SVG_USE=0

}

# HTML5 datalist support

!contains(DEFINES, ENABLE_DATALIST=.): DEFINES += ENABLE_DATALIST=1

# Tiled Backing Store support

greaterThan(QT_MINOR_VERSION, 5) {

    !contains(DEFINES, ENABLE_TILED_BACKING_STORE=.): DEFINES += ENABLE_TILED_BACKING_STORE=1

}

# Nescape plugins support (NPAPI)

!contains(DEFINES, ENABLE_NETSCAPE_PLUGIN_API=.) {

    unix|win32-*:!embedded:!wince*: {

        DEFINES += ENABLE_NETSCAPE_PLUGIN_API=1

    } else {

        DEFINES += ENABLE_NETSCAPE_PLUGIN_API=0

    }

}

# Web Socket support.

!contains(DEFINES, ENABLE_WEB_SOCKETS=.): DEFINES += ENABLE_WEB_SOCKETS=1

# Web Timing support.

!contains(DEFINES, ENABLE_WEB_TIMING=.): DEFINES += ENABLE_WEB_TIMING=0

# XSLT support with QtXmlPatterns

!contains(DEFINES, ENABLE_XSLT=.) {

    contains(QT_CONFIG, xmlpatterns):DEFINES += ENABLE_XSLT=1

    else:DEFINES += ENABLE_XSLT=0

}

# geolocation support if QtMobility exists

!CONFIG(QTDIR_build):!contains(DEFINES, ENABLE_GEOLOCATION=.) {

    contains(MOBILITY_CONFIG, location) {

       DEFINES += ENABLE_GEOLOCATION=1

    }

}

# Bearer management is part of Qt 4.7

# for older version, check for mobility with bearer 

!contains(DEFINES, ENABLE_QT_BEARER=.) {

     !lessThan(QT_MINOR_VERSION, 7) {

        DEFINES += ENABLE_QT_BEARER=1

     } else {

        contains(MOBILITY_CONFIG, bearer) {

            DEFINES += ENABLE_QT_BEARER=1

        }

    }

}

# Enable touch support with Qt 4.6

!lessThan(QT_MINOR_VERSION, 6) {

    DEFINES += ENABLE_TOUCH_EVENTS=1

    DEFINES += ENABLE_TRANSFORMACTION_EVENTS=1

}

# HTML5 Media Support

# We require QtMultimedia or Phonon

!contains(DEFINES, ENABLE_VIDEO=.) {

    DEFINES -= ENABLE_VIDEO=1

    DEFINES += ENABLE_VIDEO=0

    !lessThan(QT_MINOR_VERSION, 6):contains(MOBILITY_CONFIG, multimedia) {

        DEFINES -= ENABLE_VIDEO=0

        DEFINES += ENABLE_VIDEO=1

    } else:contains(QT_CONFIG, phonon) {

        DEFINES -= ENABLE_VIDEO=0

        DEFINES += ENABLE_VIDEO=1

    }

}

# Used to compute defaults for the build-webkit script

CONFIG(compute_defaults) {

    message($$DEFINES)

    error("Done computing defaults")

}

contains(DEFINES, ENABLE_WCSS=1) {

    contains(DEFINES, ENABLE_XHTMLMP=0) {

        DEFINES -= ENABLE_XHTMLMP=0

        DEFINES += ENABLE_XHTMLMP=1

    }

}

## Forward enabled feature macros to JavaScript enabled features macros

FEATURE_DEFINES_JAVASCRIPT = LANGUAGE_JAVASCRIPT=1

contains(DEFINES, ENABLE_CHANNEL_MESSAGING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_CHANNEL_MESSAGING=1

contains(DEFINES, ENABLE_ORIENTATION_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_ORIENTATION_EVENTS=1

contains(DEFINES, ENABLE_DASHBOARD_SUPPORT=0): DASHBOARDSUPPORTCSSPROPERTIES -= $$PWD/css/DashboardSupportCSSPropertyNames.in

contains(DEFINES, ENABLE_DATAGRID=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATAGRID=1

contains(DEFINES, ENABLE_EVENTSOURCE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_EVENTSOURCE=1

contains(DEFINES, ENABLE_DATABASE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATABASE=1

contains(DEFINES, ENABLE_DATALIST=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DATALIST=1

contains(DEFINES, ENABLE_DOM_STORAGE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_DOM_STORAGE=1

contains(DEFINES, ENABLE_SHARED_SCRIPT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_SCRIPT=1

contains(DEFINES, ENABLE_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WORKERS=1

contains(DEFINES, ENABLE_SHARED_WORKERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SHARED_WORKERS=1

contains(DEFINES, ENABLE_VIDEO=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_VIDEO=1

contains(DEFINES, ENABLE_XPATH=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XPATH=1

contains(DEFINES, ENABLE_XSLT=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XSLT=1

contains(DEFINES, ENABLE_XBL=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XBL=1

contains(DEFINES, ENABLE_FILTERS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_FILTERS=1

contains(DEFINES, ENABLE_WCSS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WCSS=1

contains(DEFINES, ENABLE_WML=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WML=1

contains(DEFINES, ENABLE_XHTMLMP=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_XHTMLMP=1

contains(DEFINES, ENABLE_SVG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_SVG=1

contains(DEFINES, ENABLE_JAVASCRIPT_DEBUGGER=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_JAVASCRIPT_DEBUGGER=1

contains(DEFINES, ENABLE_OFFLINE_WEB_APPLICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_OFFLINE_WEB_APPLICATIONS=1

contains(DEFINES, ENABLE_WEB_SOCKETS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_SOCKETS=1

contains(DEFINES, ENABLE_WEB_TIMING=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_WEB_TIMING=1

contains(DEFINES, ENABLE_TOUCH_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TOUCH_EVENTS=1

contains(DEFINES, ENABLE_TRANSFORMACTION_EVENTS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TRANSFORMACTION_EVENTS=1

contains(DEFINES, ENABLE_TILED_BACKING_STORE=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_TILED_BACKING_STORE=1

contains(DEFINES, ENABLE_NOTIFICATIONS=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_NOTIFICATIONS=1

contains(DEFINES, ENABLE_METER_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_METER_TAG=1

contains(DEFINES, ENABLE_PROGRESS_TAG=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_PROGRESS_TAG=1

contains(DEFINES, ENABLE_GEOLOCATION=1): FEATURE_DEFINES_JAVASCRIPT += ENABLE_GEOLOCATION=1

## Derived source generators

MATHML_NAMES = $$PWD/mathml/mathtags.in

WML_NAMES = $$PWD/wml/WMLTagNames.in

SVG_NAMES = $$PWD/svg/svgtags.in

XLINK_NAMES = $$PWD/svg/xlinkattrs.in

TOKENIZER = $$PWD/css/tokenizer.flex

DOCTYPESTRINGS_GPERF = $$PWD/html/DocTypeStrings.gperf

CSSBISON = $$PWD/css/CSSGrammar.y

HTML_NAMES = $$PWD/html/HTMLTagNames.in

XML_NAMES = $$PWD/xml/xmlattrs.in

XMLNS_NAMES = $$PWD/xml/xmlnsattrs.in

ENTITIES_GPERF = $$PWD/html/HTMLEntityNames.gperf

COLORDATA_GPERF = $$PWD/platform/ColorData.gperf

WALDOCSSPROPS = $$PWD/css/CSSPropertyNames.in

WALDOCSSVALUES = $$PWD/css/CSSValueKeywords.in

DASHBOARDSUPPORTCSSPROPERTIES = $$PWD/css/DashboardSupportCSSPropertyNames.in

XPATHBISON = $$PWD/xml/XPathGrammar.y

contains(DEFINES, ENABLE_SVG=1) {

    EXTRACSSPROPERTIES += $$PWD/css/SVGCSSPropertyNames.in

    EXTRACSSVALUES += $$PWD/css/SVGCSSValueKeywords.in

}

contains(DEFINES, ENABLE_WCSS=1) {

    EXTRACSSPROPERTIES += $$PWD/css/WCSSPropertyNames.in

    EXTRACSSVALUES += $$PWD/css/WCSSValueKeywords.in

}

STYLESHEETS_EMBED = \

    $$PWD/css/html.css \

    $$PWD/css/quirks.css \

    $$PWD/css/mathml.css \

    $$PWD/css/svg.css \

    $$PWD/css/view-source.css \

    $$PWD/css/wml.css \

    $$PWD/css/mediaControls.css \

    $$PWD/css/mediaControlsQt.css \

    $$PWD/css/themeQtNoListboxes.css \

    $$PWD/css/themeQtMaemo5.css

IDL_BINDINGS += \

    css/Counter.idl \

    css/CSSCharsetRule.idl \

    css/CSSFontFaceRule.idl \

    css/CSSImportRule.idl \

    css/CSSMediaRule.idl \

    css/CSSPageRule.idl \

    css/CSSPrimitiveValue.idl \

    css/CSSRule.idl \

    css/CSSRuleList.idl \

    css/CSSStyleDeclaration.idl \

    css/CSSStyleRule.idl \

    css/CSSStyleSheet.idl \

    css/CSSValue.idl \

    css/CSSValueList.idl \

    css/CSSVariablesDeclaration.idl \

    css/CSSVariablesRule.idl \

    css/MediaList.idl \

    css/Rect.idl \

    css/RGBColor.idl \

    css/StyleMedia.idl \

    css/StyleSheet.idl \

    css/StyleSheetList.idl \

    css/WebKitCSSKeyframeRule.idl \

    css/WebKitCSSKeyframesRule.idl \

    css/WebKitCSSMatrix.idl \

    css/WebKitCSSTransformValue.idl \

    dom/Attr.idl \

    dom/BeforeLoadEvent.idl \

    dom/BeforeProcessEvent.idl \

    dom/CharacterData.idl \

    dom/ClientRect.idl \

    dom/ClientRectList.idl \

    dom/Clipboard.idl \

    dom/CDATASection.idl \

    dom/Comment.idl \

    dom/CompositionEvent.idl \

    dom/CustomEvent.idl \

    dom/DeviceOrientationEvent.idl \

    dom/DocumentFragment.idl \

    dom/Document.idl \

    dom/DocumentType.idl \

    dom/DOMCoreException.idl \

    dom/DOMImplementation.idl \

    dom/DOMStringList.idl \

    dom/DOMStringMap.idl \

    dom/Element.idl \

    dom/Entity.idl \

    dom/EntityReference.idl \

    dom/ErrorEvent.idl \

    dom/Event.idl \

    dom/EventException.idl \

#    dom/EventListener.idl \

#    dom/EventTarget.idl \

    dom/KeyboardEvent.idl \

    dom/MouseEvent.idl \

    dom/MessageChannel.idl \

    dom/MessageEvent.idl \

    dom/MessagePort.idl \

    dom/MutationEvent.idl \

    dom/NamedNodeMap.idl \

    dom/Node.idl \

    dom/NodeFilter.idl \

    dom/NodeIterator.idl \

    dom/NodeList.idl \

    dom/Notation.idl \

    dom/OverflowEvent.idl \

    dom/PageTransitionEvent.idl \

    dom/PopStateEvent.idl \

    dom/ProcessingInstruction.idl \

    dom/ProgressEvent.idl \

    dom/RangeException.idl \

    dom/Range.idl \

    dom/Text.idl \

    dom/TextEvent.idl \

    dom/Touch.idl \

    dom/TouchEvent.idl \

    dom/TouchList.idl \

    dom/TransformActionEvent.idl \

    dom/TreeWalker.idl \

    dom/UIEvent.idl \

    dom/WebKitAnimationEvent.idl \

    dom/WebKitTransitionEvent.idl \

    dom/WheelEvent.idl \

    html/Blob.idl \

    html/BlobBuilder.idl \

    html/canvas/ArrayBufferView.idl \

    html/canvas/ArrayBuffer.idl \

    html/canvas/Int8Array.idl \

    html/canvas/Float32Array.idl \

    html/canvas/CanvasGradient.idl \

    html/canvas/Int32Array.idl \

    html/canvas/CanvasPattern.idl \

    html/canvas/CanvasRenderingContext.idl \

    html/canvas/CanvasRenderingContext2D.idl \

    html/canvas/WebGLActiveInfo.idl \

    html/canvas/WebGLBuffer.idl \

    html/canvas/WebGLContextAttributes.idl \

    html/canvas/WebGLFramebuffer.idl \

    html/canvas/WebGLProgram.idl \

    html/canvas/WebGLRenderbuffer.idl \

    html/canvas/WebGLRenderingContext.idl \

    html/canvas/WebGLShader.idl \

    html/canvas/Int16Array.idl \

    html/canvas/WebGLTexture.idl \

    html/canvas/WebGLUniformLocation.idl \

    html/canvas/Uint8Array.idl \

    html/canvas/Uint32Array.idl \

    html/canvas/Uint16Array.idl \

    html/DataGridColumn.idl \

    html/DataGridColumnList.idl \

    html/DOMFormData.idl \

    html/File.idl \

    html/FileError.idl \

    html/FileList.idl \

    html/FileReader.idl \

    html/HTMLAllCollection.idl \

    html/HTMLAudioElement.idl \

    html/HTMLAnchorElement.idl \

    html/HTMLAppletElement.idl \

    html/HTMLAreaElement.idl \

    html/HTMLBaseElement.idl \

    html/HTMLBaseFontElement.idl \

    html/HTMLBlockquoteElement.idl \

    html/HTMLBodyElement.idl \

    html/HTMLBRElement.idl \

    html/HTMLButtonElement.idl \

    html/HTMLCanvasElement.idl \

    html/HTMLCollection.idl \

    html/HTMLDataGridElement.idl \

    html/HTMLDataGridCellElement.idl \

    html/HTMLDataGridColElement.idl \

    html/HTMLDataGridRowElement.idl \

    html/HTMLDataListElement.idl \

    html/HTMLDirectoryElement.idl \

    html/HTMLDivElement.idl \

    html/HTMLDListElement.idl \

    html/HTMLDocument.idl \

    html/HTMLElement.idl \

    html/HTMLEmbedElement.idl \

    html/HTMLFieldSetElement.idl \

    html/HTMLFontElement.idl \

    html/HTMLFormElement.idl \

    html/HTMLFrameElement.idl \

    html/HTMLFrameSetElement.idl \

    html/HTMLHeadElement.idl \

    html/HTMLHeadingElement.idl \

    html/HTMLHRElement.idl \

    html/HTMLHtmlElement.idl \

    html/HTMLIFrameElement.idl \

    html/HTMLImageElement.idl \

    html/HTMLInputElement.idl \

    html/HTMLIsIndexElement.idl \

    html/HTMLLabelElement.idl \

    html/HTMLLegendElement.idl \

    html/HTMLLIElement.idl \

    html/HTMLLinkElement.idl \

    html/HTMLMapElement.idl \

    html/HTMLMarqueeElement.idl \

    html/HTMLMediaElement.idl \

    html/HTMLMenuElement.idl \

    html/HTMLMetaElement.idl \

    html/HTMLMeterElement.idl \

    html/HTMLModElement.idl \

    html/HTMLObjectElement.idl \

    html/HTMLOListElement.idl \

    html/HTMLOptGroupElement.idl \

    html/HTMLOptionElement.idl \

    html/HTMLOptionsCollection.idl \

    html/HTMLParagraphElement.idl \

    html/HTMLParamElement.idl \

    html/HTMLPreElement.idl \

    html/HTMLProgressElement.idl \

    html/HTMLQuoteElement.idl \

    html/HTMLScriptElement.idl \

    html/HTMLSelectElement.idl \

    html/HTMLSourceElement.idl \

    html/HTMLStyleElement.idl \

    html/HTMLTableCaptionElement.idl \

    html/HTMLTableCellElement.idl \

    html/HTMLTableColElement.idl \

    html/HTMLTableElement.idl \

    html/HTMLTableRowElement.idl \

    html/HTMLTableSectionElement.idl \

    html/HTMLTextAreaElement.idl \

    html/HTMLTitleElement.idl \

    html/HTMLUListElement.idl \

    html/HTMLVideoElement.idl \

    html/ImageData.idl \

    html/MediaError.idl \

    html/TextMetrics.idl \

    html/TimeRanges.idl \

    html/ValidityState.idl \

    html/VoidCallback.idl \

    inspector/InjectedScriptHost.idl \

    inspector/InspectorBackend.idl \

    inspector/InspectorFrontendHost.idl \

    inspector/JavaScriptCallFrame.idl \

    inspector/ScriptProfile.idl \

    inspector/ScriptProfileNode.idl \

    loader/appcache/DOMApplicationCache.idl \

    notifications/Notification.idl \

    notifications/NotificationCenter.idl \

    page/BarInfo.idl \

    page/Console.idl \

    page/Coordinates.idl \

    page/DOMSelection.idl \

    page/DOMWindow.idl \

    page/EventSource.idl \

    page/Geolocation.idl \

    page/Geoposition.idl \

    page/History.idl \

    page/Location.idl \

    page/MemoryInfo.idl \

    page/Navigation.idl \

    page/Navigator.idl \

    page/Performance.idl \

    page/PositionError.idl \

    page/Screen.idl \

    page/Timing.idl \

    page/WebKitPoint.idl \

    page/WorkerNavigator.idl \

    plugins/DOMPlugin.idl \

    plugins/DOMMimeType.idl \

    plugins/DOMPluginArray.idl \

    plugins/DOMMimeTypeArray.idl \

    storage/Database.idl \

    storage/DatabaseCallback.idl \

    storage/DatabaseSync.idl \

    storage/IDBAny.idl \

    storage/IDBDatabaseError.idl \

    storage/IDBDatabaseException.idl \

    storage/IDBDatabaseRequest.idl \

    storage/IDBErrorEvent.idl \

    storage/IDBEvent.idl \

    storage/IDBIndexRequest.idl \

    storage/IDBKey.idl \

    storage/IDBKeyRange.idl \

    storage/IDBObjectStoreRequest.idl \

    storage/IDBRequest.idl \

    storage/IDBSuccessEvent.idl \

    storage/IndexedDatabaseRequest.idl \

    storage/Storage.idl \

    storage/StorageEvent.idl \

    storage/SQLError.idl \

    storage/SQLException.idl \

    storage/SQLResultSet.idl \

    storage/SQLResultSetRowList.idl \

    storage/SQLStatementCallback.idl \

    storage/SQLStatementErrorCallback.idl \

    storage/SQLTransaction.idl \

    storage/SQLTransactionCallback.idl \

    storage/SQLTransactionErrorCallback.idl \

    storage/SQLTransactionSync.idl \

    storage/SQLTransactionSyncCallback.idl \

    svg/SVGZoomEvent.idl \

    svg/SVGAElement.idl \