#

# Copyright (c) 2009 Nokia Corporation and/or its subsidiary(-ies).

# All rights reserved.

# This component and the accompanying materials are made available

# under the terms of "Eclipse Public License v1.0"

# which accompanies this distribution, and is available

# at the URL "http://www.eclipse.org/legal/epl-v10.html".

#

# Initial Contributors:

# Nokia Corporation - initial contribution.

#

# Contributors:

#

# Description: screensaverapp project - common QMake settings

#

CONFIG += debug_and_release

# On win32 and mac, debug and release libraries are named differently.

# We must follow the debug and release settings Qt was compiled with:

# build debug iff Qt built debug, build release iff Qt built release.

win32|mac {

    !contains(QT_CONFIG,debug)|!contains(QT_CONFIG,release) {

        CONFIG -= debug_and_release debug release

        contains(QT_CONFIG,debug):  CONFIG+=debug

        contains(QT_CONFIG,release):CONFIG+=release

    }

}

CONFIG(debug, debug|release) {

    SUBDIRPART = debug

} else {

    SUBDIRPART = release

}

SOURCE_DIR = $$PWD/inc

DESTDIR = $$OUTPUT_DIR

# Add the output dirs to the link path too

LIBS += -L$$DESTDIR

DEPENDPATH += . $$SOURCE_DIR

INCLUDEPATH += . $$SOURCE_DIR

#For some reason the default include path doesn't include MOC_DIR on symbian

symbian {

    INCLUDEPATH += $$APP_LAYER_SYSTEMINCLUDE

    TARGET.CAPABILITY = ALL -TCB

    TARGET.EPOCALLOWDLLDATA=1

}

plugin: !isEmpty(PLUGIN_SUBDIR): DESTDIR = $$OUTPUT_DIR/$$PLUGIN_SUBDIR

symbian: plugin { # copy qtstub and manifest

    pluginstub.sources = $${TARGET}.dll

    pluginstub.path = $$PLUGIN_SUBDIR

    DEPLOYMENT += pluginstub

    qtplugins.path = $$PLUGIN_SUBDIR

    qtplugins.sources += qmakepluginstubs/$${TARGET}.qtplugin

    qtplugins.sources += resource/$${TARGET}.manifest

    for(qtplugin, qtplugins.sources):BLD_INF_RULES.prj_exports += "./$$qtplugin z:$$qtplugins.path/$$basename(qtplugin)"

}